-
Notifications
You must be signed in to change notification settings - Fork 730
/
Copy pathGenesis.hs
1234 lines (1086 loc) · 54.8 KB
/
Genesis.hs
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
{-# LANGUAGE ConstraintKinds #-}
{-# LANGUAGE DataKinds #-}
{-# LANGUAGE GADTs #-}
{-# LANGUAGE ScopedTypeVariables #-}
{-# LANGUAGE TupleSections #-}
{-# LANGUAGE TypeApplications #-}
{-# OPTIONS_GHC -Wno-unticked-promoted-constructors #-}
module Cardano.CLI.Shelley.Run.Genesis
( ShelleyGenesisCmdError(..)
, readShelleyGenesisWithDefault
, readAndDecodeShelleyGenesis
, readAlonzoGenesis
, runGenesisCmd
) where
import Cardano.Prelude hiding (unlines)
import Prelude (id, unlines, zip3, error)
import Data.Aeson hiding (Key)
import qualified Data.Aeson as Aeson
import qualified Data.Aeson.KeyMap as Aeson
import Data.Aeson.Encode.Pretty (encodePretty)
import qualified Data.Binary.Get as Bin
import qualified Data.ByteString.Char8 as BS
import qualified Data.ByteString.Lazy.Char8 as LBS
import Data.Coerce (coerce)
import qualified Data.List as List
import qualified Data.List.Split as List
import Data.ListMap (ListMap(ListMap))
import qualified Data.ListMap as ListMap
import qualified Data.Map.Strict as Map
import qualified Data.Sequence.Strict as Seq
import Data.String (fromString)
import qualified Data.Text as Text
import qualified Data.Text.IO as Text
import Data.Time.Clock (NominalDiffTime, UTCTime, addUTCTime, getCurrentTime, secondsToNominalDiffTime)
import Cardano.Binary (ToCBOR (..), Annotated(Annotated))
import Cardano.Crypto.Hash (HashAlgorithm)
import qualified Cardano.Crypto.Hash as Hash
import qualified Cardano.Crypto.Random as Crypto
import qualified Cardano.Crypto as CC
import Crypto.Random as Crypto
import System.Directory (createDirectoryIfMissing, listDirectory)
import System.FilePath (takeExtension, takeExtensions, (</>))
import System.IO.Error (isDoesNotExistError)
import Control.Monad.Trans.Except.Extra (firstExceptT, handleIOExceptT, hoistEither, left,
newExceptT)
import qualified Cardano.Crypto.Hash as Crypto
import Cardano.Api
import Cardano.Api.Shelley
import Cardano.Api.Byron (toByronRequiresNetworkMagic, toByronProtocolMagicId, toByronLovelace)
import Ouroboros.Consensus.BlockchainTime (SystemStart (..))
import Ouroboros.Consensus.Shelley.Eras (StandardShelley)
import Ouroboros.Consensus.Shelley.Node (ShelleyGenesisStaking (..))
import qualified Cardano.Ledger.Alonzo.Genesis as Alonzo
import qualified Cardano.Ledger.BaseTypes as Ledger
import Cardano.Ledger.Coin (Coin (..))
import qualified Cardano.Ledger.Keys as Ledger
import qualified Cardano.Ledger.Shelley.API as Ledger
import qualified Cardano.Ledger.Shelley.PParams as Shelley
import Cardano.Ledger.Crypto (ADDRHASH, Crypto, StandardCrypto)
import Cardano.Ledger.Era ()
import Cardano.CLI.Helpers (textShow)
import Cardano.CLI.Shelley.Commands
import Cardano.CLI.Shelley.Key
import Cardano.CLI.Shelley.Orphans ()
import Cardano.CLI.Shelley.Run.Address
import Cardano.CLI.Shelley.Run.Node (ShelleyNodeCmdError (..), renderShelleyNodeCmdError,
runNodeIssueOpCert, runNodeKeyGenCold, runNodeKeyGenKES, runNodeKeyGenVRF)
import Cardano.CLI.Shelley.Run.Pool (ShelleyPoolCmdError (..), renderShelleyPoolCmdError)
import Cardano.CLI.Shelley.Run.StakeAddress (ShelleyStakeAddressCmdError (..),
renderShelleyStakeAddressCmdError, runStakeAddressKeyGen)
import Cardano.CLI.Types
import Cardano.CLI.Byron.Delegation
import qualified Cardano.CLI.Byron.Key as Byron
import qualified Cardano.Crypto.Signing as Byron
import Cardano.CLI.Byron.Genesis as Byron
import Cardano.Chain.Genesis (FakeAvvmOptions (..), TestnetBalanceOptions (..), gsDlgIssuersSecrets, gsRichSecrets, gsPoorSecrets, gdProtocolParameters)
import qualified Cardano.Chain.Common as Byron (rationalToLovelacePortion, mkKnownLovelace, KeyHash)
import Cardano.Chain.Common (BlockCount(unBlockCount))
import qualified Cardano.Chain.Genesis as Genesis
import Cardano.Chain.Delegation (delegateVK)
import Cardano.Api.SerialiseTextEnvelope (textEnvelopeToJSON)
import qualified Cardano.Chain.Delegation as Dlg
import Cardano.Slotting.Slot (EpochSize(EpochSize))
import Cardano.Chain.Update
import Data.Fixed (Fixed(MkFixed))
import qualified Data.Yaml as Yaml
import Text.JSON.Canonical (parseCanonicalJSON, renderCanonicalJSON)
{- HLINT ignore "Reduce duplication" -}
data ShelleyGenesisCmdError
= ShelleyGenesisCmdAesonDecodeError !FilePath !Text
| ShelleyGenesisCmdGenesisFileReadError !(FileError IOException)
| ShelleyGenesisCmdGenesisFileDecodeError !FilePath !Text
| ShelleyGenesisCmdGenesisFileError !(FileError ())
| ShelleyGenesisCmdFileError !(FileError ())
| ShelleyGenesisCmdMismatchedGenesisKeyFiles [Int] [Int] [Int]
| ShelleyGenesisCmdFilesNoIndex [FilePath]
| ShelleyGenesisCmdFilesDupIndex [FilePath]
| ShelleyGenesisCmdTextEnvReadFileError !(FileError TextEnvelopeError)
| ShelleyGenesisCmdUnexpectedAddressVerificationKey !VerificationKeyFile !Text !SomeAddressVerificationKey
| ShelleyGenesisCmdTooFewPoolsForBulkCreds !Word !Word !Word
| ShelleyGenesisCmdAddressCmdError !ShelleyAddressCmdError
| ShelleyGenesisCmdNodeCmdError !ShelleyNodeCmdError
| ShelleyGenesisCmdPoolCmdError !ShelleyPoolCmdError
| ShelleyGenesisCmdStakeAddressCmdError !ShelleyStakeAddressCmdError
| ShelleyGenesisCmdCostModelsError !FilePath
| ShelleyGenesisCmdByronError !ByronGenesisError
deriving Show
instance Error ShelleyGenesisCmdError where
displayError err =
case err of
ShelleyGenesisCmdAesonDecodeError fp decErr ->
"Error while decoding Shelley genesis at: " <> fp <> " Error: " <> Text.unpack decErr
ShelleyGenesisCmdGenesisFileError fe -> displayError fe
ShelleyGenesisCmdFileError fe -> displayError fe
ShelleyGenesisCmdMismatchedGenesisKeyFiles gfiles dfiles vfiles ->
"Mismatch between the files found:\n"
<> "Genesis key file indexes: " <> show gfiles <> "\n"
<> "Delegate key file indexes: " <> show dfiles <> "\n"
<> "Delegate VRF key file indexes: " <> show vfiles
ShelleyGenesisCmdFilesNoIndex files ->
"The genesis keys files are expected to have a numeric index but these do not:\n"
<> unlines files
ShelleyGenesisCmdFilesDupIndex files ->
"The genesis keys files are expected to have a unique numeric index but these do not:\n"
<> unlines files
ShelleyGenesisCmdTextEnvReadFileError fileErr -> displayError fileErr
ShelleyGenesisCmdUnexpectedAddressVerificationKey (VerificationKeyFile file) expect got -> mconcat
[ "Unexpected address verification key type in file ", file
, ", expected: ", Text.unpack expect, ", got: ", show got
]
ShelleyGenesisCmdTooFewPoolsForBulkCreds pools files perPool -> mconcat
[ "Number of pools requested for generation (", show pools
, ") is insufficient to fill ", show files
, " bulk files, with ", show perPool, " pools per file."
]
ShelleyGenesisCmdAddressCmdError e -> Text.unpack $ renderShelleyAddressCmdError e
ShelleyGenesisCmdNodeCmdError e -> Text.unpack $ renderShelleyNodeCmdError e
ShelleyGenesisCmdPoolCmdError e -> Text.unpack $ renderShelleyPoolCmdError e
ShelleyGenesisCmdStakeAddressCmdError e -> Text.unpack $ renderShelleyStakeAddressCmdError e
ShelleyGenesisCmdCostModelsError fp -> "Cost model is invalid: " <> fp
ShelleyGenesisCmdGenesisFileDecodeError fp e ->
"Error while decoding Shelley genesis at: " <> fp <>
" Error: " <> Text.unpack e
ShelleyGenesisCmdGenesisFileReadError e -> displayError e
ShelleyGenesisCmdByronError e -> show e
runGenesisCmd :: GenesisCmd -> ExceptT ShelleyGenesisCmdError IO ()
runGenesisCmd (GenesisKeyGenGenesis vk sk) = runGenesisKeyGenGenesis vk sk
runGenesisCmd (GenesisKeyGenDelegate vk sk ctr) = runGenesisKeyGenDelegate vk sk ctr
runGenesisCmd (GenesisKeyGenUTxO vk sk) = runGenesisKeyGenUTxO vk sk
runGenesisCmd (GenesisCmdKeyHash vk) = runGenesisKeyHash vk
runGenesisCmd (GenesisVerKey vk sk) = runGenesisVerKey vk sk
runGenesisCmd (GenesisTxIn vk nw mOutFile) = runGenesisTxIn vk nw mOutFile
runGenesisCmd (GenesisAddr vk nw mOutFile) = runGenesisAddr vk nw mOutFile
runGenesisCmd (GenesisCreate gd gn un ms am nw) = runGenesisCreate gd gn un ms am nw
runGenesisCmd (GenesisCreateCardano gd gn un ms am k slotLength sc nw bg sg ag mNodeCfg) = runGenesisCreateCardano gd gn un ms am k slotLength sc nw bg sg ag mNodeCfg
runGenesisCmd (GenesisCreateStaked gd gn gp gl un ms am ds nw bf bp su) = runGenesisCreateStaked gd gn gp gl un ms am ds nw bf bp su
runGenesisCmd (GenesisHashFile gf) = runGenesisHashFile gf
--
-- Genesis command implementations
--
runGenesisKeyGenGenesis :: VerificationKeyFile -> SigningKeyFile
-> ExceptT ShelleyGenesisCmdError IO ()
runGenesisKeyGenGenesis (VerificationKeyFile vkeyPath)
(SigningKeyFile skeyPath) = do
skey <- liftIO $ generateSigningKey AsGenesisKey
let vkey = getVerificationKey skey
firstExceptT ShelleyGenesisCmdGenesisFileError
. newExceptT
$ writeFileTextEnvelope skeyPath (Just skeyDesc) skey
firstExceptT ShelleyGenesisCmdGenesisFileError
. newExceptT
$ writeFileTextEnvelope vkeyPath (Just vkeyDesc) vkey
where
skeyDesc, vkeyDesc :: TextEnvelopeDescr
skeyDesc = "Genesis Signing Key"
vkeyDesc = "Genesis Verification Key"
runGenesisKeyGenDelegate :: VerificationKeyFile
-> SigningKeyFile
-> OpCertCounterFile
-> ExceptT ShelleyGenesisCmdError IO ()
runGenesisKeyGenDelegate (VerificationKeyFile vkeyPath)
(SigningKeyFile skeyPath)
(OpCertCounterFile ocertCtrPath) = do
skey <- liftIO $ generateSigningKey AsGenesisDelegateKey
let vkey = getVerificationKey skey
firstExceptT ShelleyGenesisCmdGenesisFileError
. newExceptT
$ writeFileTextEnvelope skeyPath (Just skeyDesc) skey
firstExceptT ShelleyGenesisCmdGenesisFileError
. newExceptT
$ writeFileTextEnvelope vkeyPath (Just vkeyDesc) vkey
firstExceptT ShelleyGenesisCmdGenesisFileError
. newExceptT
$ writeFileTextEnvelope ocertCtrPath (Just certCtrDesc)
$ OperationalCertificateIssueCounter
initialCounter
(castVerificationKey vkey) -- Cast to a 'StakePoolKey'
where
skeyDesc, vkeyDesc, certCtrDesc :: TextEnvelopeDescr
skeyDesc = "Genesis delegate operator key"
vkeyDesc = "Genesis delegate operator key"
certCtrDesc = "Next certificate issue number: "
<> fromString (show initialCounter)
initialCounter :: Word64
initialCounter = 0
runGenesisKeyGenDelegateVRF :: VerificationKeyFile -> SigningKeyFile
-> ExceptT ShelleyGenesisCmdError IO ()
runGenesisKeyGenDelegateVRF (VerificationKeyFile vkeyPath)
(SigningKeyFile skeyPath) = do
skey <- liftIO $ generateSigningKey AsVrfKey
let vkey = getVerificationKey skey
firstExceptT ShelleyGenesisCmdGenesisFileError
. newExceptT
$ writeFileTextEnvelope skeyPath (Just skeyDesc) skey
firstExceptT ShelleyGenesisCmdGenesisFileError
. newExceptT
$ writeFileTextEnvelope vkeyPath (Just vkeyDesc) vkey
where
skeyDesc, vkeyDesc :: TextEnvelopeDescr
skeyDesc = "VRF Signing Key"
vkeyDesc = "VRF Verification Key"
runGenesisKeyGenUTxO :: VerificationKeyFile -> SigningKeyFile
-> ExceptT ShelleyGenesisCmdError IO ()
runGenesisKeyGenUTxO (VerificationKeyFile vkeyPath)
(SigningKeyFile skeyPath) = do
skey <- liftIO $ generateSigningKey AsGenesisUTxOKey
let vkey = getVerificationKey skey
firstExceptT ShelleyGenesisCmdGenesisFileError
. newExceptT
$ writeFileTextEnvelope skeyPath (Just skeyDesc) skey
firstExceptT ShelleyGenesisCmdGenesisFileError
. newExceptT
$ writeFileTextEnvelope vkeyPath (Just vkeyDesc) vkey
where
skeyDesc, vkeyDesc :: TextEnvelopeDescr
skeyDesc = "Genesis Initial UTxO Signing Key"
vkeyDesc = "Genesis Initial UTxO Verification Key"
runGenesisKeyHash :: VerificationKeyFile -> ExceptT ShelleyGenesisCmdError IO ()
runGenesisKeyHash (VerificationKeyFile vkeyPath) = do
vkey <- firstExceptT ShelleyGenesisCmdTextEnvReadFileError . newExceptT $
readFileTextEnvelopeAnyOf
[ FromSomeType (AsVerificationKey AsGenesisKey)
AGenesisKey
, FromSomeType (AsVerificationKey AsGenesisDelegateKey)
AGenesisDelegateKey
, FromSomeType (AsVerificationKey AsGenesisUTxOKey)
AGenesisUTxOKey
]
vkeyPath
liftIO $ BS.putStrLn (renderKeyHash vkey)
where
renderKeyHash :: SomeGenesisKey VerificationKey -> ByteString
renderKeyHash (AGenesisKey vk) = renderVerificationKeyHash vk
renderKeyHash (AGenesisDelegateKey vk) = renderVerificationKeyHash vk
renderKeyHash (AGenesisUTxOKey vk) = renderVerificationKeyHash vk
renderVerificationKeyHash :: Key keyrole => VerificationKey keyrole -> ByteString
renderVerificationKeyHash = serialiseToRawBytesHex
. verificationKeyHash
runGenesisVerKey :: VerificationKeyFile -> SigningKeyFile
-> ExceptT ShelleyGenesisCmdError IO ()
runGenesisVerKey (VerificationKeyFile vkeyPath) (SigningKeyFile skeyPath) = do
skey <- firstExceptT ShelleyGenesisCmdTextEnvReadFileError . newExceptT $
readFileTextEnvelopeAnyOf
[ FromSomeType (AsSigningKey AsGenesisKey)
AGenesisKey
, FromSomeType (AsSigningKey AsGenesisDelegateKey)
AGenesisDelegateKey
, FromSomeType (AsSigningKey AsGenesisUTxOKey)
AGenesisUTxOKey
]
skeyPath
let vkey :: SomeGenesisKey VerificationKey
vkey = case skey of
AGenesisKey sk -> AGenesisKey (getVerificationKey sk)
AGenesisDelegateKey sk -> AGenesisDelegateKey (getVerificationKey sk)
AGenesisUTxOKey sk -> AGenesisUTxOKey (getVerificationKey sk)
firstExceptT ShelleyGenesisCmdGenesisFileError . newExceptT . liftIO $
case vkey of
AGenesisKey vk -> writeFileTextEnvelope vkeyPath Nothing vk
AGenesisDelegateKey vk -> writeFileTextEnvelope vkeyPath Nothing vk
AGenesisUTxOKey vk -> writeFileTextEnvelope vkeyPath Nothing vk
data SomeGenesisKey f
= AGenesisKey (f GenesisKey)
| AGenesisDelegateKey (f GenesisDelegateKey)
| AGenesisUTxOKey (f GenesisUTxOKey)
runGenesisTxIn :: VerificationKeyFile -> NetworkId -> Maybe OutputFile
-> ExceptT ShelleyGenesisCmdError IO ()
runGenesisTxIn (VerificationKeyFile vkeyPath) network mOutFile = do
vkey <- firstExceptT ShelleyGenesisCmdTextEnvReadFileError . newExceptT $
readFileTextEnvelope (AsVerificationKey AsGenesisUTxOKey) vkeyPath
let txin = genesisUTxOPseudoTxIn network (verificationKeyHash vkey)
liftIO $ writeOutput mOutFile (renderTxIn txin)
runGenesisAddr :: VerificationKeyFile -> NetworkId -> Maybe OutputFile
-> ExceptT ShelleyGenesisCmdError IO ()
runGenesisAddr (VerificationKeyFile vkeyPath) network mOutFile = do
vkey <- firstExceptT ShelleyGenesisCmdTextEnvReadFileError . newExceptT $
readFileTextEnvelope (AsVerificationKey AsGenesisUTxOKey) vkeyPath
let vkh = verificationKeyHash (castVerificationKey vkey)
addr = makeShelleyAddress network (PaymentCredentialByKey vkh)
NoStakeAddress
liftIO $ writeOutput mOutFile (serialiseAddress addr)
writeOutput :: Maybe OutputFile -> Text -> IO ()
writeOutput (Just (OutputFile fpath)) = Text.writeFile fpath
writeOutput Nothing = Text.putStrLn
--
-- Create Genesis command implementation
--
runGenesisCreate :: GenesisDir
-> Word -- ^ num genesis & delegate keys to make
-> Word -- ^ num utxo keys to make
-> Maybe SystemStart
-> Maybe Lovelace
-> NetworkId
-> ExceptT ShelleyGenesisCmdError IO ()
runGenesisCreate (GenesisDir rootdir)
genNumGenesisKeys genNumUTxOKeys
mStart mAmount network = do
liftIO $ do
createDirectoryIfMissing False rootdir
createDirectoryIfMissing False gendir
createDirectoryIfMissing False deldir
createDirectoryIfMissing False utxodir
template <- readShelleyGenesisWithDefault (rootdir </> "genesis.spec.json") adjustTemplate
alonzoGenesis <- readAlonzoGenesis (rootdir </> "genesis.alonzo.spec.json")
forM_ [ 1 .. genNumGenesisKeys ] $ \index -> do
createGenesisKeys gendir index
createDelegateKeys deldir index
forM_ [ 1 .. genNumUTxOKeys ] $ \index ->
createUtxoKeys utxodir index
genDlgs <- readGenDelegsMap gendir deldir
utxoAddrs <- readInitialFundAddresses utxodir network
start <- maybe (SystemStart <$> getCurrentTimePlus30) pure mStart
let shelleyGenesis =
updateTemplate
-- Shelley genesis parameters
start genDlgs mAmount utxoAddrs mempty (Lovelace 0) [] [] template
writeFileGenesis (rootdir </> "genesis.json") shelleyGenesis
writeFileGenesis (rootdir </> "genesis.alonzo.json") alonzoGenesis
--TODO: rationalise the naming convention on these genesis json files.
where
adjustTemplate t = t { sgNetworkMagic = unNetworkMagic (toNetworkMagic network) }
gendir = rootdir </> "genesis-keys"
deldir = rootdir </> "delegate-keys"
utxodir = rootdir </> "utxo-keys"
toSKeyJSON :: Key a => SigningKey a -> ByteString
toSKeyJSON = LBS.toStrict . textEnvelopeToJSON Nothing
toVkeyJSON :: Key a => SigningKey a -> ByteString
toVkeyJSON = LBS.toStrict . textEnvelopeToJSON Nothing . getVerificationKey
toVkeyJSON' :: Key a => VerificationKey a -> ByteString
toVkeyJSON' = LBS.toStrict . textEnvelopeToJSON Nothing
toOpCert :: (OperationalCertificate, OperationalCertificateIssueCounter) -> ByteString
toOpCert = LBS.toStrict . textEnvelopeToJSON Nothing . fst
toCounter :: (OperationalCertificate, OperationalCertificateIssueCounter) -> ByteString
toCounter = LBS.toStrict . textEnvelopeToJSON Nothing . snd
generateShelleyNodeSecrets :: [SigningKey GenesisDelegateExtendedKey] -> [VerificationKey GenesisKey]
-> IO (Map (Hash GenesisKey)
( Hash GenesisDelegateKey, Hash VrfKey)
, [SigningKey VrfKey]
, [SigningKey KesKey]
, [(OperationalCertificate, OperationalCertificateIssueCounter)])
generateShelleyNodeSecrets shelleyDelegateKeys shelleyGenesisvkeys = do
let
shelleyDelegatevkeys :: [VerificationKey GenesisDelegateKey]
shelleyDelegatevkeys = map (castVerificationKey . getVerificationKey) shelleyDelegateKeys
vrfKeys <- forM shelleyDelegateKeys $ \_ -> generateSigningKey AsVrfKey
kesKeys <- forM shelleyDelegateKeys $ \_ -> generateSigningKey AsKesKey
let
opCertInputs :: [(VerificationKey KesKey, SigningKey GenesisDelegateExtendedKey)]
opCertInputs = zip (map getVerificationKey kesKeys) shelleyDelegateKeys
createOpCert :: (VerificationKey KesKey, SigningKey GenesisDelegateExtendedKey) -> (OperationalCertificate, OperationalCertificateIssueCounter)
createOpCert (kesKey, delegateKey) = either (error . show) identity eResult
where
eResult = issueOperationalCertificate kesKey (Right delegateKey) (KESPeriod 0) counter
counter = OperationalCertificateIssueCounter 0 (convert . getVerificationKey $ delegateKey)
convert :: VerificationKey GenesisDelegateExtendedKey
-> VerificationKey StakePoolKey
convert = (castVerificationKey :: VerificationKey GenesisDelegateKey
-> VerificationKey StakePoolKey)
. (castVerificationKey :: VerificationKey GenesisDelegateExtendedKey
-> VerificationKey GenesisDelegateKey)
opCerts :: [(OperationalCertificate, OperationalCertificateIssueCounter)]
opCerts = map createOpCert opCertInputs
vrfvkeys = map getVerificationKey vrfKeys
combinedMap :: [ ( VerificationKey GenesisKey
, VerificationKey GenesisDelegateKey
, VerificationKey VrfKey
)
]
combinedMap = zip3 shelleyGenesisvkeys shelleyDelegatevkeys vrfvkeys
hashKeys :: (VerificationKey GenesisKey, VerificationKey GenesisDelegateKey, VerificationKey VrfKey) -> (Hash GenesisKey, (Hash GenesisDelegateKey, Hash VrfKey))
hashKeys (genesis,delegate,vrf) = (verificationKeyHash genesis, (verificationKeyHash delegate, verificationKeyHash vrf));
delegateMap :: Map (Hash GenesisKey) (Hash GenesisDelegateKey, Hash VrfKey)
delegateMap = Map.fromList . map hashKeys $ combinedMap
return (delegateMap, vrfKeys, kesKeys, opCerts)
--
-- Create Genesis Cardano command implementation
--
runGenesisCreateCardano :: GenesisDir
-> Word -- ^ num genesis & delegate keys to make
-> Word -- ^ num utxo keys to make
-> Maybe SystemStart
-> Maybe Lovelace
-> BlockCount
-> Word -- ^ slot length in ms
-> Rational
-> NetworkId
-> FilePath -- ^ Byron Genesis
-> FilePath -- ^ Shelley Genesis
-> FilePath -- ^ Alonzo Genesis
-> Maybe FilePath
-> ExceptT ShelleyGenesisCmdError IO ()
runGenesisCreateCardano (GenesisDir rootdir)
genNumGenesisKeys _genNumUTxOKeys
mStart mAmount mSecurity slotLength mSlotCoeff
network byronGenesisT shelleyGenesisT alonzoGenesisT mNodeCfg = do
start <- maybe (SystemStart <$> getCurrentTimePlus30) pure mStart
(byronGenesis', byronSecrets) <- convertToShelleyError $ Byron.mkGenesis $ byronParams start
let
byronGenesis = byronGenesis'
{ gdProtocolParameters = (gdProtocolParameters byronGenesis') {
ppSlotDuration = floor ( toRational slotLength * recip mSlotCoeff )
}
}
genesisKeys = gsDlgIssuersSecrets byronSecrets
byronGenesisKeys = map ByronSigningKey genesisKeys
shelleyGenesisKeys = map convertGenesisKey genesisKeys
shelleyGenesisvkeys :: [VerificationKey GenesisKey]
shelleyGenesisvkeys = map (castVerificationKey . getVerificationKey) shelleyGenesisKeys
delegateKeys = gsRichSecrets byronSecrets
byronDelegateKeys = map ByronSigningKey delegateKeys
shelleyDelegateKeys :: [SigningKey GenesisDelegateExtendedKey]
shelleyDelegateKeys = map convertDelegate delegateKeys
shelleyDelegatevkeys :: [VerificationKey GenesisDelegateKey]
shelleyDelegatevkeys = map (castVerificationKey . getVerificationKey) shelleyDelegateKeys
utxoKeys = gsPoorSecrets byronSecrets
byronUtxoKeys = map (ByronSigningKey . Genesis.poorSecretToKey) utxoKeys
shelleyUtxoKeys = map (convertPoor . Genesis.poorSecretToKey) utxoKeys
dlgCerts <- convertToShelleyError $ mapM (findDelegateCert byronGenesis) byronDelegateKeys
let
overrideShelleyGenesis t = t
{ sgNetworkMagic = unNetworkMagic (toNetworkMagic network)
, sgNetworkId = toShelleyNetwork network
, sgActiveSlotsCoeff = fromMaybe (error $ "Could not convert from Rational: " ++ show mSlotCoeff) $ Ledger.boundRational mSlotCoeff
, sgSecurityParam = unBlockCount mSecurity
, sgUpdateQuorum = fromIntegral $ ((genNumGenesisKeys `div` 3) * 2) + 1
, sgEpochLength = EpochSize $ floor $ (fromIntegral (unBlockCount mSecurity) * 10) / mSlotCoeff
, sgMaxLovelaceSupply = 45000000000000000
, sgSystemStart = getSystemStart start
, sgSlotLength = secondsToNominalDiffTime $ MkFixed (fromIntegral slotLength) * 1000000000
}
shelleyGenesisTemplate <- liftIO $ overrideShelleyGenesis . fromRight (error "shelley genesis template not found") <$> readAndDecodeShelleyGenesis shelleyGenesisT
alonzoGenesis <- readAlonzoGenesis alonzoGenesisT
(delegateMap, vrfKeys, kesKeys, opCerts) <- liftIO $ generateShelleyNodeSecrets shelleyDelegateKeys shelleyGenesisvkeys
let
shelleyGenesis :: ShelleyGenesis StandardShelley
shelleyGenesis = updateTemplate start delegateMap Nothing [] mempty 0 [] [] shelleyGenesisTemplate
liftIO $ do
createDirectoryIfMissing False rootdir
createDirectoryIfMissing False gendir
createDirectoryIfMissing False deldir
createDirectoryIfMissing False utxodir
writeSecrets gendir "byron" "key" serialiseToRawBytes byronGenesisKeys
writeSecrets gendir "shelley" "skey" toSKeyJSON shelleyGenesisKeys
writeSecrets gendir "shelley" "vkey" toVkeyJSON shelleyGenesisKeys
writeSecrets deldir "byron" "key" serialiseToRawBytes byronDelegateKeys
writeSecrets deldir "shelley" "skey" toSKeyJSON shelleyDelegateKeys
writeSecrets deldir "shelley" "vkey" toVkeyJSON' shelleyDelegatevkeys
writeSecrets deldir "shelley" "vrf.skey" toSKeyJSON vrfKeys
writeSecrets deldir "shelley" "vrf.vkey" toVkeyJSON vrfKeys
writeSecrets deldir "shelley" "kes.skey" toSKeyJSON kesKeys
writeSecrets deldir "shelley" "kes.vkey" toVkeyJSON kesKeys
writeSecrets utxodir "byron" "key" serialiseToRawBytes byronUtxoKeys
writeSecrets utxodir "shelley" "skey" toSKeyJSON shelleyUtxoKeys
writeSecrets utxodir "shelley" "vkey" toVkeyJSON shelleyUtxoKeys
writeSecrets deldir "byron" "cert.json" serialiseDelegationCert dlgCerts
writeSecrets deldir "shelley" "opcert.json" toOpCert opCerts
writeSecrets deldir "shelley" "counter.json" toCounter opCerts
LBS.writeFile (rootdir </> "byron-genesis.json") (canonicalEncodePretty byronGenesis)
writeFileGenesis (rootdir </> "shelley-genesis.json") shelleyGenesis
writeFileGenesis (rootdir </> "alonzo-genesis.json") alonzoGenesis
liftIO $ do
case mNodeCfg of
Nothing -> pure ()
Just nodeCfg -> do
nodeConfig <- Yaml.decodeFileThrow nodeCfg
let
hashShelleyGenesis :: ToJSON genesis => genesis -> Text
hashShelleyGenesis genesis = Crypto.hashToTextAsHex gh
where
content :: ByteString
content = LBS.toStrict $ encodePretty genesis
gh :: Crypto.Hash Crypto.Blake2b_256 ByteString
gh = Crypto.hashWith id content
hashByronGenesis :: Genesis.GenesisData -> Text
hashByronGenesis genesis = Crypto.hashToTextAsHex genesisHash
where
genesisHash :: Crypto.Hash Crypto.Blake2b_256 ByteString
genesisHash = Crypto.hashWith id
. LBS.toStrict
. renderCanonicalJSON
. either (error "error parsing json that was just encoded!?") identity
. parseCanonicalJSON
. canonicalEncodePretty $ genesis
-- TODO, NodeConfig needs a ToJSON instance
updateConfig :: Yaml.Value -> Yaml.Value
updateConfig (Object obj) = Object
$ (Aeson.insert "ByronGenesisHash" . String . hashByronGenesis) byronGenesis
$ (Aeson.insert "ShelleyGenesisHash" . String . hashShelleyGenesis) shelleyGenesis
$ (Aeson.insert "AlonzoGenesisHash" . String . hashShelleyGenesis) alonzoGenesis
obj
updateConfig x = x
newConfig :: Yaml.Value
newConfig = updateConfig nodeConfig
encodeFile (rootdir </> "node-config.json") newConfig
where
convertToShelleyError = withExceptT ShelleyGenesisCmdByronError
convertGenesisKey :: Byron.SigningKey -> SigningKey GenesisExtendedKey
convertGenesisKey (Byron.SigningKey xsk) = GenesisExtendedSigningKey xsk
convertDelegate :: Byron.SigningKey -> SigningKey GenesisDelegateExtendedKey
convertDelegate (Byron.SigningKey xsk) = GenesisDelegateExtendedSigningKey xsk
convertPoor :: Byron.SigningKey -> SigningKey ByronKey
convertPoor = ByronSigningKey
byronParams start = Byron.GenesisParameters (getSystemStart start) byronGenesisT mSecurity byronNetwork byronBalance byronFakeAvvm byronAvvmFactor Nothing
gendir = rootdir </> "genesis-keys"
deldir = rootdir </> "delegate-keys"
utxodir = rootdir </> "utxo-keys"
byronNetwork = CC.AProtocolMagic
(Annotated (toByronProtocolMagicId network) ())
(toByronRequiresNetworkMagic network)
byronBalance = TestnetBalanceOptions
{ tboRichmen = genNumGenesisKeys
, tboPoors = 1
, tboTotalBalance = fromMaybe zeroLovelace $ toByronLovelace (fromMaybe 0 mAmount)
, tboRichmenShare = 0
}
byronFakeAvvm = FakeAvvmOptions
{ faoCount = 0
, faoOneBalance = zeroLovelace
}
byronAvvmFactor = Byron.rationalToLovelacePortion 0.0
zeroLovelace = Byron.mkKnownLovelace @0
-- Compare a given 'SigningKey' with a 'Certificate' 'VerificationKey'
isCertForSK :: CC.SigningKey -> Dlg.Certificate -> Bool
isCertForSK sk cert = delegateVK cert == CC.toVerification sk
findDelegateCert :: Genesis.GenesisData -> SigningKey ByronKey -> ExceptT ByronGenesisError IO Dlg.Certificate
findDelegateCert byronGenesis bSkey@(ByronSigningKey sk) = do
case find (isCertForSK sk) (Map.elems $ dlgCertMap byronGenesis) of
Nothing -> throwE . NoGenesisDelegationForKey
. Byron.prettyPublicKey $ getVerificationKey bSkey
Just x -> pure x
dlgCertMap :: Genesis.GenesisData -> Map Byron.KeyHash Dlg.Certificate
dlgCertMap byronGenesis = Genesis.unGenesisDelegation $ Genesis.gdHeavyDelegation byronGenesis
runGenesisCreateStaked
:: GenesisDir
-> Word -- ^ num genesis & delegate keys to make
-> Word -- ^ num utxo keys to make
-> Word -- ^ num pools to make
-> Word -- ^ num delegators to make
-> Maybe SystemStart
-> Maybe Lovelace -- ^ supply going to non-delegators
-> Lovelace -- ^ supply going to delegators
-> NetworkId
-> Word -- ^ bulk credential files to write
-> Word -- ^ pool credentials per bulk file
-> Word -- ^ num stuffed UTxO entries
-> ExceptT ShelleyGenesisCmdError IO ()
runGenesisCreateStaked (GenesisDir rootdir)
genNumGenesisKeys genNumUTxOKeys genNumPools genNumStDelegs
mStart mNonDlgAmount stDlgAmount network
bulkPoolCredFiles bulkPoolsPerFile numStuffedUtxo = do
liftIO $ do
createDirectoryIfMissing False rootdir
createDirectoryIfMissing False gendir
createDirectoryIfMissing False deldir
createDirectoryIfMissing False pooldir
createDirectoryIfMissing False stdeldir
createDirectoryIfMissing False utxodir
template <- readShelleyGenesisWithDefault (rootdir </> "genesis.spec.json") adjustTemplate
alonzoGenesis <- readAlonzoGenesis (rootdir </> "genesis.alonzo.spec.json")
forM_ [ 1 .. genNumGenesisKeys ] $ \index -> do
createGenesisKeys gendir index
createDelegateKeys deldir index
forM_ [ 1 .. genNumUTxOKeys ] $ \index ->
createUtxoKeys utxodir index
pools <- forM [ 1 .. genNumPools ] $ \index -> do
createPoolCredentials pooldir index
buildPool network pooldir index
when (bulkPoolCredFiles * bulkPoolsPerFile > genNumPools) $
left $ ShelleyGenesisCmdTooFewPoolsForBulkCreds genNumPools bulkPoolCredFiles bulkPoolsPerFile
-- We generate the bulk files for the last pool indices,
-- so that all the non-bulk pools have stable indices at beginning:
let bulkOffset = fromIntegral $ genNumPools - bulkPoolCredFiles * bulkPoolsPerFile
bulkIndices :: [Word] = [ 1 + bulkOffset .. genNumPools ]
bulkSlices :: [[Word]] = List.chunksOf (fromIntegral bulkPoolsPerFile) bulkIndices
forM_ (zip [ 1 .. bulkPoolCredFiles ] bulkSlices) $
uncurry (writeBulkPoolCredentials pooldir)
forM_ [ 1 .. genNumStDelegs ] $ \index ->
createDelegatorCredentials stdeldir index
delegations :: [Delegation] <-
-- Distribute M delegates across N pools:
forM [ (pool, delegIx)
| (pool, poolIx) <- zip pools [1 ..]
, delegIxLocal <- [ 1 .. delegsPerPool ] ++
-- Add all remaining delegates to the last pool:
if delegsRemaining /= 0 && poolIx == genNumPools
then [ delegsPerPool + 1 .. delegsPerPool + delegsRemaining ]
else []
, let delegIx = delegIxLocal + delegsPerPool * (poolIx - 1)] $
uncurry (computeDelegation network stdeldir)
genDlgs <- readGenDelegsMap gendir deldir
nonDelegAddrs <- readInitialFundAddresses utxodir network
start <- maybe (SystemStart <$> getCurrentTimePlus30) pure mStart
stuffedUtxoAddrs <- liftIO $ replicateM (fromIntegral numStuffedUtxo)
genStuffedAddress
let poolMap :: Map (Ledger.KeyHash Ledger.Staking StandardCrypto) (Ledger.PoolParams StandardCrypto)
poolMap = Map.fromList $ mkDelegationMapEntry <$> delegations
delegAddrs = dInitialUtxoAddr <$> delegations
shelleyGenesis =
updateTemplate
-- Shelley genesis parameters
start genDlgs mNonDlgAmount nonDelegAddrs poolMap
stDlgAmount delegAddrs stuffedUtxoAddrs template
writeFileGenesis (rootdir </> "genesis.json") shelleyGenesis
writeFileGenesis (rootdir </> "genesis.alonzo.json") alonzoGenesis
--TODO: rationalise the naming convention on these genesis json files.
liftIO $ Text.putStrLn $ mconcat $
[ "generated genesis with: "
, textShow genNumGenesisKeys, " genesis keys, "
, textShow genNumUTxOKeys, " non-delegating UTxO keys, "
, textShow genNumPools, " stake pools, "
, textShow genNumStDelegs, " delegating UTxO keys, "
, textShow (length delegations), " delegation relationships, "
, textShow (Map.size poolMap), " delegation map entries, "
, textShow (length delegAddrs), " delegating addresses"
] ++
[ mconcat
[ ", "
, textShow bulkPoolCredFiles, " bulk pool credential files, "
, textShow bulkPoolsPerFile, " pools per bulk credential file, indices starting from "
, textShow bulkOffset, ", "
, textShow $ length bulkIndices, " total pools in bulk nodes, each bulk node having this many entries: "
, textShow $ length <$> bulkSlices
]
| bulkPoolCredFiles * bulkPoolsPerFile > 0 ]
where
(,) delegsPerPool delegsRemaining = divMod genNumStDelegs genNumPools
adjustTemplate t = t { sgNetworkMagic = unNetworkMagic (toNetworkMagic network) }
mkDelegationMapEntry :: Delegation -> (Ledger.KeyHash Ledger.Staking StandardCrypto, Ledger.PoolParams StandardCrypto)
mkDelegationMapEntry d = (dDelegStaking d, dPoolParams d)
gendir = rootdir </> "genesis-keys"
deldir = rootdir </> "delegate-keys"
pooldir = rootdir </> "pools"
stdeldir = rootdir </> "stake-delegator-keys"
utxodir = rootdir </> "utxo-keys"
genStuffedAddress :: IO (AddressInEra ShelleyEra)
genStuffedAddress =
shelleyAddressInEra <$>
(ShelleyAddress
<$> pure Ledger.Testnet
<*> (Ledger.KeyHashObj . mkKeyHash . read64BitInt
<$> Crypto.runSecureRandom (getRandomBytes 8))
<*> pure Ledger.StakeRefNull)
read64BitInt :: ByteString -> Int
read64BitInt = (fromIntegral :: Word64 -> Int)
. Bin.runGet Bin.getWord64le . LBS.fromStrict
mkDummyHash :: forall h a. HashAlgorithm h => Proxy h -> Int -> Hash.Hash h a
mkDummyHash _ = coerce . Ledger.hashWithSerialiser @h toCBOR
mkKeyHash :: forall c discriminator. Crypto c => Int -> Ledger.KeyHash discriminator c
mkKeyHash = Ledger.KeyHash . mkDummyHash (Proxy @(ADDRHASH c))
-- -------------------------------------------------------------------------------------------------
createDelegateKeys :: FilePath -> Word -> ExceptT ShelleyGenesisCmdError IO ()
createDelegateKeys dir index = do
liftIO $ createDirectoryIfMissing False dir
runGenesisKeyGenDelegate
(VerificationKeyFile $ dir </> "delegate" ++ strIndex ++ ".vkey")
coldSK
opCertCtr
runGenesisKeyGenDelegateVRF
(VerificationKeyFile $ dir </> "delegate" ++ strIndex ++ ".vrf.vkey")
(SigningKeyFile $ dir </> "delegate" ++ strIndex ++ ".vrf.skey")
firstExceptT ShelleyGenesisCmdNodeCmdError $ do
runNodeKeyGenKES
kesVK
(SigningKeyFile $ dir </> "delegate" ++ strIndex ++ ".kes.skey")
runNodeIssueOpCert
(VerificationKeyFilePath kesVK)
coldSK
opCertCtr
(KESPeriod 0)
(OutputFile $ dir </> "opcert" ++ strIndex ++ ".cert")
where
strIndex = show index
kesVK = VerificationKeyFile $ dir </> "delegate" ++ strIndex ++ ".kes.vkey"
coldSK = SigningKeyFile $ dir </> "delegate" ++ strIndex ++ ".skey"
opCertCtr = OpCertCounterFile $ dir </> "delegate" ++ strIndex ++ ".counter"
createGenesisKeys :: FilePath -> Word -> ExceptT ShelleyGenesisCmdError IO ()
createGenesisKeys dir index = do
liftIO $ createDirectoryIfMissing False dir
let strIndex = show index
runGenesisKeyGenGenesis
(VerificationKeyFile $ dir </> "genesis" ++ strIndex ++ ".vkey")
(SigningKeyFile $ dir </> "genesis" ++ strIndex ++ ".skey")
createUtxoKeys :: FilePath -> Word -> ExceptT ShelleyGenesisCmdError IO ()
createUtxoKeys dir index = do
liftIO $ createDirectoryIfMissing False dir
let strIndex = show index
runGenesisKeyGenUTxO
(VerificationKeyFile $ dir </> "utxo" ++ strIndex ++ ".vkey")
(SigningKeyFile $ dir </> "utxo" ++ strIndex ++ ".skey")
createPoolCredentials :: FilePath -> Word -> ExceptT ShelleyGenesisCmdError IO ()
createPoolCredentials dir index = do
liftIO $ createDirectoryIfMissing False dir
firstExceptT ShelleyGenesisCmdNodeCmdError $ do
runNodeKeyGenKES
kesVK
(SigningKeyFile $ dir </> "kes" ++ strIndex ++ ".skey")
runNodeKeyGenVRF
(VerificationKeyFile $ dir </> "vrf" ++ strIndex ++ ".vkey")
(SigningKeyFile $ dir </> "vrf" ++ strIndex ++ ".skey")
runNodeKeyGenCold
(VerificationKeyFile $ dir </> "cold" ++ strIndex ++ ".vkey")
coldSK
opCertCtr
runNodeIssueOpCert
(VerificationKeyFilePath kesVK)
coldSK
opCertCtr
(KESPeriod 0)
(OutputFile $ dir </> "opcert" ++ strIndex ++ ".cert")
firstExceptT ShelleyGenesisCmdStakeAddressCmdError $
runStakeAddressKeyGen
(VerificationKeyFile $ dir </> "staking-reward" ++ strIndex ++ ".vkey")
(SigningKeyFile $ dir </> "staking-reward" ++ strIndex ++ ".skey")
where
strIndex = show index
kesVK = VerificationKeyFile $ dir </> "kes" ++ strIndex ++ ".vkey"
coldSK = SigningKeyFile $ dir </> "cold" ++ strIndex ++ ".skey"
opCertCtr = OpCertCounterFile $ dir </> "opcert" ++ strIndex ++ ".counter"
createDelegatorCredentials :: FilePath -> Word -> ExceptT ShelleyGenesisCmdError IO ()
createDelegatorCredentials dir index = do
liftIO $ createDirectoryIfMissing False dir
firstExceptT ShelleyGenesisCmdAddressCmdError $ do
runAddressKeyGen
AddressKeyShelley
addrVK
(SigningKeyFile $ dir </> "payment" ++ strIndex ++ ".skey")
firstExceptT ShelleyGenesisCmdStakeAddressCmdError $
runStakeAddressKeyGen
(VerificationKeyFile $ dir </> "staking" ++ strIndex ++ ".vkey")
(SigningKeyFile $ dir </> "staking" ++ strIndex ++ ".skey")
where
strIndex = show index
addrVK = VerificationKeyFile $ dir </> "payment" ++ strIndex ++ ".vkey"
data Delegation
= Delegation
{ dInitialUtxoAddr :: AddressInEra ShelleyEra
, dDelegStaking :: Ledger.KeyHash Ledger.Staking StandardCrypto
, dPoolParams :: Ledger.PoolParams StandardCrypto
}
buildPool :: NetworkId -> FilePath -> Word -> ExceptT ShelleyGenesisCmdError IO (Ledger.PoolParams StandardCrypto)
buildPool nw dir index = do
StakePoolVerificationKey poolColdVK <- firstExceptT (ShelleyGenesisCmdPoolCmdError
. ShelleyPoolCmdReadFileError)
. newExceptT
$ readFileTextEnvelope (AsVerificationKey AsStakePoolKey) poolColdVKF
VrfVerificationKey poolVrfVK <- firstExceptT (ShelleyGenesisCmdNodeCmdError
. ShelleyNodeCmdReadFileError)
. newExceptT
$ readFileTextEnvelope (AsVerificationKey AsVrfKey) poolVrfVKF
rewardsSVK <- firstExceptT ShelleyGenesisCmdTextEnvReadFileError
. newExceptT
$ readFileTextEnvelope (AsVerificationKey AsStakeKey) poolRewardVKF
pure Ledger.PoolParams
{ Ledger._poolId = Ledger.hashKey poolColdVK
, Ledger._poolVrf = Ledger.hashVerKeyVRF poolVrfVK
, Ledger._poolPledge = Ledger.Coin 0
, Ledger._poolCost = Ledger.Coin 0
, Ledger._poolMargin = minBound
, Ledger._poolRAcnt =
toShelleyStakeAddr $ makeStakeAddress nw $ StakeCredentialByKey (verificationKeyHash rewardsSVK)
, Ledger._poolOwners = mempty
, Ledger._poolRelays = Seq.empty
, Ledger._poolMD = Ledger.SNothing
}
where
strIndex = show index
poolColdVKF = dir </> "cold" ++ strIndex ++ ".vkey"
poolVrfVKF = dir </> "vrf" ++ strIndex ++ ".vkey"
poolRewardVKF = dir </> "staking-reward" ++ strIndex ++ ".vkey"
writeBulkPoolCredentials :: FilePath -> Word -> [Word] -> ExceptT ShelleyGenesisCmdError IO ()
writeBulkPoolCredentials dir bulkIx poolIxs = do
creds <- mapM readPoolCreds poolIxs
handleIOExceptT (ShelleyGenesisCmdFileError . FileIOError bulkFile) $
LBS.writeFile bulkFile $ Aeson.encode creds
where
bulkFile = dir </> "bulk" ++ show bulkIx ++ ".creds"
readPoolCreds :: Word -> ExceptT ShelleyGenesisCmdError IO
(TextEnvelope, TextEnvelope, TextEnvelope)
readPoolCreds ix = do
(,,) <$> readEnvelope poolCert
<*> readEnvelope poolVrfSKF
<*> readEnvelope poolKesSKF
where
strIndex = show ix
poolCert = dir </> "opcert" ++ strIndex ++ ".cert"
poolVrfSKF = dir </> "vrf" ++ strIndex ++ ".skey"
poolKesSKF = dir </> "kes" ++ strIndex ++ ".skey"
readEnvelope :: FilePath -> ExceptT ShelleyGenesisCmdError IO TextEnvelope
readEnvelope fp = do
content <- handleIOExceptT (ShelleyGenesisCmdFileError . FileIOError fp) $
BS.readFile fp
firstExceptT (ShelleyGenesisCmdAesonDecodeError fp . Text.pack) . hoistEither $
Aeson.eitherDecodeStrict' content
computeDelegation :: NetworkId -> FilePath -> Ledger.PoolParams StandardCrypto -> Word -> ExceptT ShelleyGenesisCmdError IO Delegation
computeDelegation nw delegDir pool delegIx = do
paySVK <- firstExceptT (ShelleyGenesisCmdAddressCmdError
. ShelleyAddressCmdVerificationKeyTextOrFileError) $
readAddressVerificationKeyTextOrFile
(VktofVerificationKeyFile payVKF)
initialUtxoAddr <- case paySVK of
APaymentVerificationKey payVK ->
firstExceptT ShelleyGenesisCmdAddressCmdError
$ buildShelleyAddress payVK (Just . StakeVerifierKey . VerificationKeyFilePath . VerificationKeyFile $ stakeVKF) nw
_ -> left $ ShelleyGenesisCmdUnexpectedAddressVerificationKey payVKF "APaymentVerificationKey" paySVK
StakeVerificationKey stakeVK <- firstExceptT ShelleyGenesisCmdTextEnvReadFileError
. newExceptT
$ readFileTextEnvelope (AsVerificationKey AsStakeKey) stakeVKF
pure Delegation
{ dInitialUtxoAddr = shelleyAddressInEra initialUtxoAddr
, dDelegStaking = Ledger.hashKey stakeVK
, dPoolParams = pool
}
where
strIndexDeleg = show delegIx
payVKF = VerificationKeyFile $ delegDir </> "payment" ++ strIndexDeleg ++ ".vkey"
stakeVKF = delegDir </> "staking" ++ strIndexDeleg ++ ".vkey"
-- | Current UTCTime plus 30 seconds
getCurrentTimePlus30 :: ExceptT a IO UTCTime
getCurrentTimePlus30 =
plus30sec <$> liftIO getCurrentTime
where
plus30sec :: UTCTime -> UTCTime
plus30sec = addUTCTime (30 :: NominalDiffTime)
-- | Attempts to read Shelley genesis from disk
-- and if not found creates a default Shelley genesis.
readShelleyGenesisWithDefault
:: FilePath
-> (ShelleyGenesis StandardShelley -> ShelleyGenesis StandardShelley)
-> ExceptT ShelleyGenesisCmdError IO (ShelleyGenesis StandardShelley)
readShelleyGenesisWithDefault fpath adjustDefaults = do
newExceptT (readAndDecodeShelleyGenesis fpath)
`catchError` \err ->
case err of
ShelleyGenesisCmdGenesisFileReadError (FileIOError _ ioe)
| isDoesNotExistError ioe -> writeDefault
_ -> left err
where
defaults :: ShelleyGenesis StandardShelley
defaults = adjustDefaults shelleyGenesisDefaults
writeDefault = do
handleIOExceptT (ShelleyGenesisCmdGenesisFileError . FileIOError fpath) $
LBS.writeFile fpath (encodePretty defaults)
return defaults
readAndDecodeShelleyGenesis
:: FilePath
-> IO (Either ShelleyGenesisCmdError (ShelleyGenesis StandardShelley))
readAndDecodeShelleyGenesis fpath = runExceptT $ do
lbs <- handleIOExceptT (ShelleyGenesisCmdGenesisFileReadError . FileIOError fpath) $ LBS.readFile fpath
firstExceptT (ShelleyGenesisCmdGenesisFileDecodeError fpath . Text.pack)
. hoistEither $ Aeson.eitherDecode' lbs
updateTemplate
:: SystemStart
-- Genesis delegation (not stake-based):
-> Map (Hash GenesisKey) (Hash GenesisDelegateKey, Hash VrfKey)
-- Non-delegated initial UTxO spec:
-> Maybe Lovelace
-> [AddressInEra ShelleyEra]
-- Genesis staking: pools/delegation map & delegated initial UTxO spec: