socket_service.pp

# @summary Create a systemd socket activated service
# @api public
#
# Systemd socket activated services have their own dependencies. This is a
# convenience wrapper around systemd::unit_file.
#
# @param name [Pattern['^[^/]+$']]
#   The target unit file to create
define systemd::socket_service (
  Enum['running', 'stopped', 'present', 'absent'] $ensure = 'running',
  Optional[String[1]] $socket_content = undef,
  Optional[String[1]] $service_content = undef,
) {
  assert_type(Pattern['^[^/]+$'], $name)

  if $ensure != 'absent' {
    assert_type(NotUndef, $socket_content)
    assert_type(NotUndef, $service_content)
  }

  $active = $ensure ? {
    'running' => true,
    'stopped' => false,
    'absent'  => false,
    default   => undef,
  }

  $unit_file_ensure = bool2str($ensure == 'absent', 'absent', 'present')

  systemd::unit_file { "${name}.socket":
    ensure  => $unit_file_ensure,
    content => $socket_content,
    active  => $active,
    enable  => $active,
  }

  systemd::unit_file { "${name}.service":
    ensure  => $unit_file_ensure,
    content => $service_content,
    active  => $active,
    enable  => $active,
  }

  if $active {
    File["/etc/systemd/system/${name}.socket"] -> Service["${name}.service"]
  }
}