Support recompiling local Mix.install/2 dependencies (#13375)

Author: jonatanklosko

Diff for: lib/iex/lib/iex/helpers.ex

@@ -69,17 +69,22 @@ defmodule IEx.Helpers do
   import IEx, only: [dont_display_result: 0]
 
   @doc """
-  Recompiles the current Mix project.
+  Recompiles the current Mix project or Mix install
+  dependencies.
 
-  This helper only works when IEx is started with a Mix
-  project, for example, `iex -S mix`. Note this function
-  simply recompiles Elixir modules, without reloading
-  configuration, recompiling dependencies, or restarting
-  applications.
+  This helper requires either `Mix.install/2` to have been
+  called within the current IEx session or for IEx to be
+  started alongside, for example, `iex -S mix`.
 
-  Therefore, any long running process may crash on recompilation,
-  as changed modules will be temporarily removed and recompiled,
-  without going through the proper code change callback.
+  In the `Mix.install/1` case, it will recompile any outdated
+  path dependency declared during install. Within a project,
+  it will recompile any outdated module.
+
+  Note this function simply recompiles Elixir modules, without
+  reloading configuration or restarting applications. This means
+  any long running process may crash on recompilation, as changed
+  modules will be temporarily removed and recompiled, without
+  going through the proper code change callback.
 
   If you want to reload a single module, consider using
   `r(ModuleName)` instead.
@@ -93,19 +98,30 @@ defmodule IEx.Helpers do
 
   """
   def recompile(options \\ []) do
-    if mix_started?() do
-      project = Mix.Project.get()
-
-      if is_nil(project) or
-           project.__info__(:compile)[:source] == String.to_charlist(Path.absname("mix.exs")) do
-        do_recompile(options)
-      else
-        message = "Cannot recompile because the current working directory changed"
-        IO.puts(IEx.color(:eval_error, message))
-      end
-    else
-      IO.puts(IEx.color(:eval_error, "Mix is not running. Please start IEx with: iex -S mix"))
-      :error
+    cond do
+      not mix_started?() ->
+        IO.puts(IEx.color(:eval_error, "Mix is not running. Please start IEx with: iex -S mix"))
+        :error
+
+      Mix.installed?() ->
+        Mix.in_install_project(fn ->
+          do_recompile(options)
+          # Just as with Mix.install/2 we clear all task invocations,
+          # so that we can recompile the dependencies again next time
+          Mix.Task.clear()
+          :ok
+        end)
+
+      true ->
+        project = Mix.Project.get()
+
+        if is_nil(project) or
+             project.__info__(:compile)[:source] == String.to_charlist(Path.absname("mix.exs")) do
+          do_recompile(options)
+        else
+          message = "Cannot recompile because the current working directory changed"
+          IO.puts(IEx.color(:eval_error, message))
+        end
     end
   end
 

Diff for: lib/mix/lib/mix.ex

@@ -855,23 +855,14 @@ defmodule Mix do
           File.rm_rf!(install_dir)
         end
 
-        config = [
-          version: "0.1.0",
-          build_embedded: false,
-          build_per_environment: true,
-          build_path: "_build",
-          lockfile: "mix.lock",
-          deps_path: "deps",
+        dynamic_config = [
           deps: deps,
-          app: :mix_install,
-          erlc_paths: [],
-          elixirc_paths: [],
-          compilers: [],
           consolidate_protocols: consolidate_protocols?,
-          config_path: config_path,
-          prune_code_paths: false
+          config_path: config_path
         ]
 
+        config = install_project_config(dynamic_config)
+
         started_apps = Application.started_applications()
         :ok = Mix.ProjectStack.push(@mix_install_project, config, "nofile")
         build_dir = Path.join(install_dir, "_build")
@@ -937,13 +928,18 @@ defmodule Mix do
             end
           end
 
-          Mix.State.put(:installed, id)
+          Mix.State.put(:installed, {id, dynamic_config})
           :ok
         after
           Mix.ProjectStack.pop()
+          # Clear all tasks invoked during installation, since there
+          # is no reason to keep this in memory. Additionally this
+          # allows us to rerun tasks for the dependencies later on,
+          # such as recompilation
+          Mix.Task.clear()
         end
 
-      ^id when not force? ->
+      {^id, _dynamic_config} when not force? ->
         :ok
 
       _ ->
@@ -978,6 +974,45 @@ defmodule Mix do
     Path.join([install_root, version, cache_id])
   end
 
+  defp install_project_config(dynamic_config) do
+    [
+      version: "0.1.0",
+      build_embedded: false,
+      build_per_environment: true,
+      build_path: "_build",
+      lockfile: "mix.lock",
+      deps_path: "deps",
+      app: :mix_install,
+      erlc_paths: [],
+      elixirc_paths: [],
+      compilers: [],
+      prune_code_paths: false
+    ] ++ dynamic_config
+  end
+
+  @doc false
+  def in_install_project(fun) do
+    case Mix.State.get(:installed) do
+      {id, dynamic_config} ->
+        config = install_project_config(dynamic_config)
+
+        install_dir = install_dir(id)
+
+        File.cd!(install_dir, fn ->
+          :ok = Mix.ProjectStack.push(@mix_install_project, config, "nofile")
+
+          try do
+            fun.()
+          after
+            Mix.ProjectStack.pop()
+          end
+        end)
+
+      nil ->
+        Mix.raise("trying to call Mix.in_install_project/1, but Mix.install/2 was never called")
+    end
+  end
+
   @doc """
   Returns whether `Mix.install/2` was called in the current node.
   """

Diff for: lib/mix/test/mix_test.exs

@@ -39,7 +39,7 @@ defmodule MixTest do
       assert Protocol.consolidated?(InstallTest.Protocol)
 
       assert_received {:mix_shell, :info, ["==> install_test"]}
-      assert_received {:mix_shell, :info, ["Compiling 1 file (.ex)"]}
+      assert_received {:mix_shell, :info, ["Compiling 2 files (.ex)"]}
       assert_received {:mix_shell, :info, ["Generated install_test app"]}
       refute_received _
 
@@ -67,7 +67,7 @@ defmodule MixTest do
 
       assert File.dir?(Path.join(tmp_dir, "installs"))
       assert_received {:mix_shell, :info, ["==> install_test"]}
-      assert_received {:mix_shell, :info, ["Compiling 1 file (.ex)"]}
+      assert_received {:mix_shell, :info, ["Compiling 2 files (.ex)"]}
       assert_received {:mix_shell, :info, ["Generated install_test app"]}
       refute_received _
 
@@ -345,6 +345,36 @@ defmodule MixTest do
       assert Mix.installed?()
     end
 
+    test "in_install_project", %{tmp_dir: tmp_dir} do
+      Mix.install([
+        {:install_test, path: Path.join(tmp_dir, "install_test")}
+      ])
+
+      Mix.in_install_project(fn ->
+        config = Mix.Project.config()
+        assert [{:install_test, [path: _]}] = config[:deps]
+      end)
+    end
+
+    test "in_install_project recompile", %{tmp_dir: tmp_dir} do
+      Mix.install([
+        {:install_test, path: Path.join(tmp_dir, "install_test")}
+      ])
+
+      File.write!("#{tmp_dir}/install_test/lib/install_test.ex", """
+      defmodule InstallTest do
+        def hello do
+          :universe
+        end
+      end
+      """)
+
+      Mix.in_install_project(fn ->
+        Mix.Task.run("compile")
+        assert apply(InstallTest, :hello, []) == :universe
+      end)
+    end
+
     defp test_project(%{tmp_dir: tmp_dir}) do
       path = :code.get_path()
 
@@ -384,7 +414,9 @@ defmodule MixTest do
           :world
         end
       end
+      """)
 
+      File.write!("#{tmp_dir}/install_test/lib/install_test_protocol.ex", """
       defprotocol InstallTest.Protocol do
         def foo(x)
       end