feat: sitemap extension (#45)

Co-authored-by: Mitchell Hanberg <[email protected]>

Author: paradox460

lib/tableau/extensions/sitemap_extension.ex

@@ -0,0 +1,97 @@
+defmodule Tableau.SitemapExtension.Config do
+  @moduledoc false
+
+  def new(input), do: {:ok, input}
+end
+
+defmodule Tableau.SitemapExtension do
+  @moduledoc """
+  Generate a sitemap.xml for your site, for improved search-engine indexing.
+
+  ## Configuration
+
+  - `:enabled` - boolean - Extension is active or not.
+
+  ### Example
+
+  ```elixir
+  config :tableau, Tableau.SitemapExtension,
+    enabled: true,
+  ```
+
+  ## Custom attributes
+
+  Any page may add attributes to its sitemap `<url>` entry by adding a `sitemap` entry, with a map of elements to add
+
+  ### Frontmatter
+
+  ```yaml
+  title: "Some Page"
+  sitemap:
+    priority: 0.8
+    changefreq: hourly
+  ```
+
+  ### `Tableau.Page`
+
+  ```elixir
+  defmodule MySite.AboutPage do
+    use Tableau.Page,
+      layout: MySite.RootLayout,
+      permalink: "/about",
+      sitemap: %{priority: 0.8, changefreq: "monthly"}
+
+    # ...
+  end
+  ```
+
+  Generated sitemap is stored in the root of your site, at /sitemap.xml.
+
+  For more information about sitemaps, see <https://www.sitemaps.org>.
+  """
+
+  use Tableau.Extension, key: :sitemap, type: :post_write, priority: 300
+
+  def run(%{site: %{config: %{url: root}, pages: pages}} = token) do
+    urls =
+      for page <- pages, uniq: true do
+        loc =
+          [{:loc, nil, URI.merge(root, page.permalink)}]
+          |> prepend_lastmod(page)
+          |> prepend_sitemap_assigns(page)
+
+        {:url, nil, loc}
+      end
+
+    xml =
+      XmlBuilder.document(
+        :urlset,
+        [
+          xmlns: "http://www.sitemaps.org/schemas/sitemap/0.9",
+          "xmlns:xsi": "http://www.w3.org/2001/XMLSchema-instance",
+          "xsi:schemaLocation":
+            "http://www.sitemaps.org/schemas/sitemap/0.9 http://www.sitemaps.org/schemas/sitemap/0.9/sitemap.xsd"
+        ],
+        urls
+      )
+
+    File.mkdir_p!("_site")
+    File.write!("_site/sitemap.xml", XmlBuilder.generate_iodata(xml))
+
+    {:ok, token}
+  end
+
+  defp prepend_lastmod(body, %{date: date}) do
+    [{:lastmod, nil, DateTime.to_iso8601(date)} | body]
+  end
+
+  defp prepend_lastmod(body, _), do: body
+
+  defp prepend_sitemap_assigns(body, %{sitemap: sitemap_data}) do
+    for {key, value} <- sitemap_data, reduce: body do
+      acc -> [{key, [], value} | acc]
+    end
+  end
+
+  defp prepend_sitemap_assigns(body, _), do: body
+end

mix.exs

@@ -44,6 +44,7 @@ defmodule Tableau.MixProject do
       {:websock_adapter, "~> 0.5"},
       {:yaml_elixir, "~> 2.9"},
       {:floki, "~> 0.34"},
+      {:xml_builder, "~> 2.1"},
 
       # dev
       {:ex_doc, ">= 0.0.0", only: :dev},

mix.lock

@@ -27,6 +27,7 @@
   "web_dev_utils": {:hex, :web_dev_utils, "0.1.0", "0c41285667b4c9944eaa2c3189f22ec3a915c349c4b879b5ae023e8ca0824657", [:mix], [{:file_system, "~> 0.2", [hex: :file_system, repo: "hexpm", optional: false]}], "hexpm", "af82e1723fe76c09d817a9a9baf85160f7ed572cb4af854194d3f7609ae92f10"},
   "websock": {:hex, :websock, "0.5.3", "2f69a6ebe810328555b6fe5c831a851f485e303a7c8ce6c5f675abeb20ebdadc", [:mix], [], "hexpm", "6105453d7fac22c712ad66fab1d45abdf049868f253cf719b625151460b8b453"},
   "websock_adapter": {:hex, :websock_adapter, "0.5.4", "7af8408e7ed9d56578539594d1ee7d8461e2dd5c3f57b0f2a5352d610ddde757", [:mix], [{:bandit, ">= 0.6.0", [hex: :bandit, repo: "hexpm", optional: true]}, {:plug, "~> 1.14", [hex: :plug, repo: "hexpm", optional: false]}, {:plug_cowboy, "~> 2.6", [hex: :plug_cowboy, repo: "hexpm", optional: true]}, {:websock, "~> 0.5", [hex: :websock, repo: "hexpm", optional: false]}], "hexpm", "d2c238c79c52cbe223fcdae22ca0bb5007a735b9e933870e241fce66afb4f4ab"},
+  "xml_builder": {:hex, :xml_builder, "2.2.0", "cc5f1eeefcfcde6e90a9b77fb6c490a20bc1b856a7010ce6396f6da9719cbbab", [:mix], [], "hexpm", "9d66d52fb917565d358166a4314078d39ef04d552904de96f8e73f68f64a62c9"},
   "yamerl": {:hex, :yamerl, "0.10.0", "4ff81fee2f1f6a46f1700c0d880b24d193ddb74bd14ef42cb0bcf46e81ef2f8e", [:rebar3], [], "hexpm", "346adb2963f1051dc837a2364e4acf6eb7d80097c0f53cbdc3046ec8ec4b4e6e"},
   "yaml_elixir": {:hex, :yaml_elixir, "2.9.0", "9a256da867b37b8d2c1ffd5d9de373a4fda77a32a45b452f1708508ba7bbcb53", [:mix], [{:yamerl, "~> 0.10", [hex: :yamerl, repo: "hexpm", optional: false]}], "hexpm", "0cb0e7d4c56f5e99a6253ed1a670ed0e39c13fc45a6da054033928607ac08dfc"},
 }