Allow alias's actual to be None

Summary:
I found this useful for expressing `hashbrown`'s conditional dependency on `allocator-api2`. `actual = None` is a way to disappear a dependency at the incoming edge (like how `incoming_transition` applies), as opposed to the outgoing edge (like `transition_dep`).

```lang=toml
# fixups/hashbrown/fixups.toml

# Hashbrown does not really depend on allocator-api2 but `cargo metadata` is
# claiming that it is, likely because of rust-lang/cargo#10801
omit_deps = ["allocator_api2"]
extra_deps = ["//allocator:allocator-api2"]

[rustc_flags_select]
"//constraints:compiler" = []
"//constraints:library" = ["-Zforce-unstable-if-unmarked"]
```

```lang=starlark
# allocator/BUCK

alias(
    name = "allocator-api2",
    actual = select({
        "//constraints:library": None,  # <---
        "//constraints:compiler": "//:allocator-api2",
    }),
    visibility = ["//:"],
)
```

```lang=starlark
# BUCK, generated by Reindeer

rust_bootstrap_library(
    name = "hashbrown-0.15.2",
    srcs = [":hashbrown-0.15.2.crate"],
    crate = "hashbrown",
    crate_root = "hashbrown-0.15.2.crate/src/lib.rs",
    edition = "2021",
    features = select({
        "//constraints:compiler": ["default-hasher"],
        "//constraints:library": [
            "alloc",
            "compiler_builtins",
            "core",
            "nightly",
            "raw-entry",
            "rustc-dep-of-std",
            "rustc-internal-api",
        ],
    }),
    named_deps = select({
        "//constraints:compiler": {},
        "//constraints:library": {
            "alloc": ":rustc-std-workspace-alloc-1.99.0",
            "core": ":rustc-std-workspace-core-1.99.0",
        },
    }),
    rustc_flags = select({
        "//constraints:compiler": [],
        "//constraints:library": ["-Zforce-unstable-if-unmarked"],
    }),
    visibility = [],
    deps = select({
        "//constraints:compiler": [
            ":foldhash-0.1.5",
            "//allocator:allocator-api2",
        ],
        "//constraints:library": [
            ":compiler_builtins-0.1.146",
            "//allocator:allocator-api2",
        ],
    }),
)
```

The correct dependency would be something like `deps = ... + select({"//constraints:library": [], "//constraints:compiler": ["//:allocator-api2"]})` but this is not something that Reindeer's `extra_deps` can express. Maybe when we drop TOML and use Starlark fixups.

Note that this diff does not use `attrs.option(..., default = None)` so the new meaning of `None` only kicks in if `actual = None` is written explicitly, as opposed to by default when `actual` is omitted from the `alias` call.

Reviewed By: JakobDegen

Differential Revision: D73325154

fbshipit-source-id: 9618446cc1762933fbb476ad20e3c9f5d1877d4c

Author: David Tolnay

prelude/alias.bzl

@@ -8,7 +8,10 @@
 # Implementation of aliases build rules.
 
 def alias_impl(ctx: AnalysisContext) -> list[Provider]:
-    return ctx.attrs.actual.providers
+    if ctx.attrs.actual:
+        return ctx.attrs.actual.providers
+    else:
+        return [DefaultInfo()]
 
 def configured_alias_impl(ctx: AnalysisContext) -> list[Provider]:
     if ctx.attrs.configured_actual != None and ctx.attrs.fallback_actual != None:
@@ -19,9 +22,6 @@ def configured_alias_impl(ctx: AnalysisContext) -> list[Provider]:
         return ctx.attrs.fallback_actual.providers
     fail("must set one of `configured_actual` or `fallback_actual`")
 
-def toolchain_alias_impl(ctx: AnalysisContext) -> list[Provider]:
-    return ctx.attrs.actual.providers
-
 def versioned_alias_impl(_ctx: AnalysisContext) -> list[Provider]:
     # Should be intercepted in macro stub and converted to `alias`.
     fail("unsupported")

prelude/decls/core_rules.bzl

@@ -30,7 +30,7 @@ alias = prelude_rule(
     attrs = (
         # @unsorted-dict-items
         {
-            "actual": attrs.dep(pulls_and_pushes_plugins = plugins.All),
+            "actual": attrs.option(attrs.dep(pulls_and_pushes_plugins = plugins.All)),
             "contacts": attrs.list(attrs.string(), default = []),
             "default_host_platform": attrs.option(attrs.configuration_label(), default = None),
             "labels": attrs.list(attrs.string(), default = []),
@@ -1092,7 +1092,9 @@ expected to be a toolchain_rule as well.
     """,
     examples = None,
     further = None,
-    attrs = {"actual": attrs.toolchain_dep(doc = "The actual toolchain that is being aliased. This should be a toolchain rule.")},
+    attrs = {
+        "actual": attrs.option(attrs.toolchain_dep(doc = "The actual toolchain that is being aliased. This should be a toolchain rule.")),
+    },
 )
 
 versioned_alias = prelude_rule(

prelude/rules_impl.bzl

@@ -5,7 +5,7 @@
 # License, Version 2.0 found in the LICENSE-APACHE file in the root directory
 # of this source tree.
 
-load("@prelude//:alias.bzl", "alias_impl", "configured_alias_impl", "toolchain_alias_impl", "versioned_alias_impl")
+load("@prelude//:alias.bzl", "alias_impl", "configured_alias_impl", "versioned_alias_impl")
 load("@prelude//:command_alias.bzl", "command_alias_impl")
 load("@prelude//:export_file.bzl", "export_file_impl")
 load("@prelude//:filegroup.bzl", "filegroup_impl")
@@ -155,7 +155,7 @@ extra_implemented_rules = struct(
     sh_binary = sh_binary_impl,
     sh_test = sh_test_impl,
     test_suite = test_suite_impl,
-    toolchain_alias = toolchain_alias_impl,
+    toolchain_alias = alias_impl,
     versioned_alias = versioned_alias_impl,
     worker_tool = worker_tool,