|
| 1 | +# SPDX-Identifier: MIT |
| 2 | + |
| 3 | +#[[.rst: |
| 4 | +Find test-drive |
| 5 | +--------------- |
| 6 | +
|
| 7 | +Makes the test-drive project available. |
| 8 | +
|
| 9 | +Imported Targets |
| 10 | +^^^^^^^^^^^^^^^^ |
| 11 | +
|
| 12 | +This module provides the following imported target, if found: |
| 13 | +
|
| 14 | +``test-drive::test-drive`` |
| 15 | + The test-drive library |
| 16 | +
|
| 17 | +
|
| 18 | +Result Variables |
| 19 | +^^^^^^^^^^^^^^^^ |
| 20 | +
|
| 21 | +This module will define the following variables: |
| 22 | +
|
| 23 | +``TEST_DRIVE_FOUND`` |
| 24 | + True if the test-drive library is available |
| 25 | +
|
| 26 | +``TEST_DRIVE_SOURCE_DIR`` |
| 27 | + Path to the source directory of the test-drive project, |
| 28 | + only set if the project is included as source. |
| 29 | +
|
| 30 | +``TEST_DRIVE_BINARY_DIR`` |
| 31 | + Path to the binary directory of the test-drive project, |
| 32 | + only set if the project is included as source. |
| 33 | +
|
| 34 | +Cache variables |
| 35 | +^^^^^^^^^^^^^^^ |
| 36 | +
|
| 37 | +The following cache variables may be set to influence the library detection: |
| 38 | +
|
| 39 | +``TEST_DRIVE_FIND_METHOD`` |
| 40 | + Methods to find or make the project available. Available methods are |
| 41 | + - ``cmake``: Try to find via CMake config file |
| 42 | + - ``pkgconf``: Try to find via pkg-config file |
| 43 | + - ``subproject``: Use source in subprojects directory |
| 44 | + - ``fetch``: Fetch the source from upstream |
| 45 | +
|
| 46 | +``TEST_DRIVE_DIR`` |
| 47 | + Used for searching the CMake config file |
| 48 | +
|
| 49 | +``TEST_DRIVE_SUBPROJECT`` |
| 50 | + Directory to find the test-drive subproject, relative to the project root |
| 51 | +
|
| 52 | +#]] |
| 53 | + |
| 54 | +set(_lib "test-drive") |
| 55 | +set(_pkg "TEST_DRIVE") |
| 56 | +set(_url "https://github.com/fortran-lang/test-drive") |
| 57 | + |
| 58 | +if(NOT DEFINED "${_pkg}_FIND_METHOD") |
| 59 | + if(DEFINED "${PROJECT_NAME}-dependency-method") |
| 60 | + set("${_pkg}_FIND_METHOD" "${${PROJECT_NAME}-dependency-method}") |
| 61 | + else() |
| 62 | + set("${_pkg}_FIND_METHOD" "cmake" "pkgconf" "subproject" "fetch") |
| 63 | + endif() |
| 64 | + set("_${_pkg}_FIND_METHOD") |
| 65 | +endif() |
| 66 | + |
| 67 | +foreach(method ${${_pkg}_FIND_METHOD}) |
| 68 | + if(TARGET "${_lib}::${_lib}") |
| 69 | + break() |
| 70 | + endif() |
| 71 | + |
| 72 | + if("${method}" STREQUAL "cmake") |
| 73 | + message(STATUS "${_lib}: Find installed package") |
| 74 | + if(DEFINED "${_pkg}_DIR") |
| 75 | + set("_${_pkg}_DIR") |
| 76 | + set("${_lib}_DIR" "${_pkg}_DIR") |
| 77 | + endif() |
| 78 | + find_package("${_lib}" CONFIG QUIET) |
| 79 | + if("${_lib}_FOUND") |
| 80 | + message(STATUS "${_lib}: Found installed package") |
| 81 | + break() |
| 82 | + endif() |
| 83 | + endif() |
| 84 | + |
| 85 | + if("${method}" STREQUAL "pkgconf") |
| 86 | + find_package(PkgConfig QUIET) |
| 87 | + pkg_check_modules("${_pkg}" QUIET "${_lib}") |
| 88 | + if("${_pkg}_FOUND") |
| 89 | + message(STATUS "Found ${_lib} via pkg-config") |
| 90 | + |
| 91 | + add_library("${_lib}::${_lib}" INTERFACE IMPORTED) |
| 92 | + target_link_libraries( |
| 93 | + "${_lib}::${_lib}" |
| 94 | + INTERFACE |
| 95 | + "${${_pkg}_LINK_LIBRARIES}" |
| 96 | + ) |
| 97 | + target_include_directories( |
| 98 | + "${_lib}::${_lib}" |
| 99 | + INTERFACE |
| 100 | + "${${_pkg}_INCLUDE_DIRS}" |
| 101 | + ) |
| 102 | + |
| 103 | + break() |
| 104 | + endif() |
| 105 | + endif() |
| 106 | + |
| 107 | + if("${method}" STREQUAL "subproject") |
| 108 | + if(NOT DEFINED "${_pkg}_SUBPROJECT") |
| 109 | + set("_${_pkg}_SUBPROJECT") |
| 110 | + set("${_pkg}_SUBPROJECT" "subprojects/${_lib}") |
| 111 | + endif() |
| 112 | + set("${_pkg}_SOURCE_DIR" "${PROJECT_SOURCE_DIR}/${${_pkg}_SUBPROJECT}") |
| 113 | + set("${_pkg}_BINARY_DIR" "${PROJECT_BINARY_DIR}/${${_pkg}_SUBPROJECT}") |
| 114 | + if(EXISTS "${${_pkg}_SOURCE_DIR}/CMakeLists.txt") |
| 115 | + message(STATUS "Include ${_lib} from ${${_pkg}_SUBPROJECT}") |
| 116 | + add_subdirectory( |
| 117 | + "${${_pkg}_SOURCE_DIR}" |
| 118 | + "${${_pkg}_BINARY_DIR}" |
| 119 | + ) |
| 120 | + |
| 121 | + add_library("${_lib}::${_lib}" INTERFACE IMPORTED) |
| 122 | + target_link_libraries("${_lib}::${_lib}" INTERFACE "${_lib}") |
| 123 | + |
| 124 | + # We need the module directory in the subproject before we finish the configure stage |
| 125 | + if(NOT EXISTS "${${_pkg}_BINARY_DIR}/include") |
| 126 | + make_directory("${${_pkg}_BINARY_DIR}/include") |
| 127 | + endif() |
| 128 | + |
| 129 | + break() |
| 130 | + endif() |
| 131 | + endif() |
| 132 | + |
| 133 | + if("${method}" STREQUAL "fetch") |
| 134 | + message(STATUS "Retrieving ${_lib} from ${_url}") |
| 135 | + include(FetchContent) |
| 136 | + FetchContent_Declare( |
| 137 | + "${_lib}" |
| 138 | + GIT_REPOSITORY "${_url}" |
| 139 | + GIT_TAG "HEAD" |
| 140 | + ) |
| 141 | + FetchContent_MakeAvailable("${_lib}") |
| 142 | + |
| 143 | + add_library("${_lib}::${_lib}" INTERFACE IMPORTED) |
| 144 | + target_link_libraries("${_lib}::${_lib}" INTERFACE "${_lib}") |
| 145 | + |
| 146 | + # We need the module directory in the subproject before we finish the configure stage |
| 147 | + FetchContent_GetProperties("${_lib}" SOURCE_DIR "${_pkg}_SOURCE_DIR") |
| 148 | + FetchContent_GetProperties("${_lib}" BINARY_DIR "${_pkg}_BINARY_DIR") |
| 149 | + if(NOT EXISTS "${${_pkg}_BINARY_DIR}/include") |
| 150 | + make_directory("${${_pkg}_BINARY_DIR}/include") |
| 151 | + endif() |
| 152 | + |
| 153 | + break() |
| 154 | + endif() |
| 155 | + |
| 156 | +endforeach() |
| 157 | + |
| 158 | +if(TARGET "${_lib}::${_lib}") |
| 159 | + set("${_pkg}_FOUND" TRUE) |
| 160 | +else() |
| 161 | + set("${_pkg}_FOUND" FALSE) |
| 162 | +endif() |
| 163 | + |
| 164 | +if(DEFINED "_${_pkg}_SUBPROJECT") |
| 165 | + unset("${_pkg}_SUBPROJECT") |
| 166 | + unset("_${_pkg}_SUBPROJECT") |
| 167 | +endif() |
| 168 | +if(DEFINED "_${_pkg}_DIR") |
| 169 | + unset("${_lib}_DIR") |
| 170 | + unset("_${_pkg}_DIR") |
| 171 | +endif() |
| 172 | +if(DEFINED "_${_pkg}_FIND_METHOD") |
| 173 | + unset("${_pkg}_FIND_METHOD") |
| 174 | + unset("_${_pkg}_FIND_METHOD") |
| 175 | +endif() |
| 176 | +unset(_lib) |
| 177 | +unset(_pkg) |
| 178 | +unset(_url) |
0 commit comments