feat: add zprint formatter for clojure

Author: agriffis

Diff for: autoload/codefmt/zprint.vim

@@ -0,0 +1,81 @@
+" Copyright 2019 Google Inc. All rights reserved.
+"
+" Licensed under the Apache License, Version 2.0 (the "License");
+" you may not use this file except in compliance with the License.
+" You may obtain a copy of the License at
+"
+"     http://www.apache.org/licenses/LICENSE-2.0
+"
+" Unless required by applicable law or agreed to in writing, software
+" distributed under the License is distributed on an "AS IS" BASIS,
+" WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+" See the License for the specific language governing permissions and
+" limitations under the License.
+
+
+let s:plugin = maktaba#plugin#Get('codefmt')
+
+let s:supported_filetypes = ['clojure']
+
+
+""
+" @private
+" Formatter: zprint
+function! codefmt#zprint#GetFormatter() abort
+  let l:formatter = {
+        \ 'name': 'zprint',
+        \ 'setup_instructions':
+        \ 'Install zprint filter (https://github.com/kkinnear/zprint) ' .
+        \ 'and configure the zprint_executable flag'}
+
+  function l:formatter.IsAvailable() abort
+    return executable(s:plugin.Flag('zprint_executable'))
+  endfunction
+
+  function l:formatter.AppliesToBuffer() abort
+    return index(s:supported_filetypes, &filetype) >= 0
+  endfunction
+
+  ""
+  " Reformat the current buffer with zprint or the binary named in
+  " @flag(zprint_executable), only targeting the range between {startline} and
+  " {endline}.
+  function l:formatter.FormatRange(startline, endline) abort
+    let l:zprint_options = s:plugin.Flag('zprint_options')
+    if maktaba#value#IsCallable(l:zprint_options)
+      let l:zprint_options = maktaba#function#Call(l:zprint_options)
+    elseif type(l:zprint_options) isnot# type([])
+      throw maktaba#error#WrongType(
+            \ 'zprint_options flag must be list or callable. Found %s',
+            \ string(l:zprint_options))
+    endif
+    let l:cmd = [s:plugin.Flag('zprint_executable')]
+    call extend(l:cmd, l:zprint_options)
+
+    call maktaba#ensure#IsNumber(a:startline)
+    call maktaba#ensure#IsNumber(a:endline)
+    let l:lines = getline(1, line('$'))
+
+    " zprint doesn't support formatting a range of lines, so format the range
+    " individually, ignoring context. This works well for top-level forms, although it's
+    " not ideal for inner forms because it loses the indentation.
+    let l:input = join(l:lines[a:startline - 1 : a:endline - 1], "\n")
+
+    " Prepare the syscall, optionally changing to the containing directory for
+    " the sake of {:search-config? true}.
+    let l:syscall = maktaba#syscall#Create(l:cmd).WithStdin(l:input)
+    if s:plugin.Flag('zprint_chdir')
+      let l:syscall = l:syscall.WithCwd(expand('%:p:h'))
+    endif
+    let l:result = l:syscall.Call()
+    let l:formatted = split(l:result.stdout, "\n")
+
+    " Special case empty slice: neither l:lines[:0] nor l:lines[:-1] is right.
+    let l:before = a:startline > 1 ? l:lines[ : a:startline - 2] : []
+    let l:full_formatted = l:before + l:formatted + l:lines[a:endline :]
+
+    call maktaba#buffer#Overwrite(1, line('$'), l:full_formatted)
+  endfunction
+
+  return l:formatter
+endfunction

Diff for: instant/flags.vim

@@ -115,3 +115,18 @@ call s:plugin.Flag('prettier_options', [
 ""
 " The path to the prettier executable.
 call s:plugin.Flag('prettier_executable', 'prettier')
+
+""
+" Whether and where to change directory before calling zprint. If this is true,
+" then changes directory (temporarily) to location of file, so that
+" :search-config? can be effective.
+call s:plugin.Flag('zprint_chdir', v:true)
+
+""
+" Command line arguments to feed zprint. Either a list or callable that takes no
+" args and returns a list with command line arguments.
+call s:plugin.Flag('zprint_options', ['{:search-config? true}'])
+
+""
+" The path to the zprint executable.
+call s:plugin.Flag('zprint_executable', 'zprint')

Diff for: plugin/register.vim

@@ -34,3 +34,4 @@ call s:registry.AddExtension(codefmt#gn#GetFormatter())
 call s:registry.AddExtension(codefmt#buildifier#GetFormatter())
 call s:registry.AddExtension(codefmt#googlejava#GetFormatter())
 call s:registry.AddExtension(codefmt#shfmt#GetFormatter())
+call s:registry.AddExtension(codefmt#zprint#GetFormatter())

Diff for: vroom/zprint.vroom

@@ -0,0 +1,81 @@
+The zprint formatter knows how to format Clojure.
+If you aren't familiar with basic codefmt usage yet, see main.vroom first.
+
+We'll set up codefmt and configure the vroom environment, then jump into some
+examples.
+
+  :source $VROOMDIR/setupvroom.vim
+
+  :let g:repeat_calls = []
+  :function FakeRepeat(...)<CR>
+  |  call add(g:repeat_calls, a:000)<CR>
+  :endfunction
+  :call maktaba#test#Override('repeat#set', 'FakeRepeat')
+
+  :call codefmt#SetWhetherToPerformIsAvailableChecksForTesting(0)
+
+
+The zprint formatter expects the zprint executable to be installed on your system.
+
+  % (defn x [] (cond nil 1 :else 2))
+  :FormatCode zprint
+  ! zprint .*
+  $ (defn x
+  $   []
+  $   (cond nil 1
+  $         :else 2))
+
+The name or path of the zprint executable can be configured via the
+zprint_executable flag if the default of "zprint" doesn't work.
+
+  :Glaive codefmt zprint_executable='myzprint'
+  :FormatCode zprint
+  ! myzprint .*
+  $ (defn x
+  $   []
+  $   (cond nil 1
+  $         :else 2))
+  :Glaive codefmt zprint_executable='zprint'
+
+
+You can format any buffer with zprint specifying the formatter explicitly.
+
+  @clear
+  % (defn x [] (cond nil 1 :else 2))
+
+  :FormatCode zprint
+  ! zprint .*2>.*
+  (defn x
+    []
+    (cond nil 1
+          :else 2))
+  @end
+
+It can format specific line ranges of code using :FormatLines.
+
+  @clear
+  % (defn x [] (cond nil 1 :else 2))<CR>
+  |(defn x [] (cond nil 1 :else 2))
+
+  :1,1FormatLines zprint
+  ! zprint .*
+  $ (defn x
+  $   []
+  $   (cond nil 1
+  $         :else 2))
+  (defn x
+    []
+    (cond nil 1
+          :else 2))
+  (defn x [] (cond nil 1 :else 2))
+  @end
+
+It is also the default formatter for the clojure file type.
+
+  @clear
+  % (defn x [] (cond nil 1 :else 2))
+
+  :set filetype=clojure
+  :FormatCode
+  ! zprint .*
+  $ (defn x [] (cond nil 1 :else 2))