Added websocket, proxy, epoll as feature capabilities

Added pom publications for features
Workaround for publishing gradle metadata to bintray

Author: SgtSilvio

Diff for: build.gradle

@@ -8,7 +8,6 @@ buildscript {
 }
 
 plugins {
-    id 'nebula.optional-base' version '3.0.3'
     id 'com.github.johnrengelman.shadow' version '4.0.4' apply false
     id 'biz.aQute.bnd.builder' version '4.2.0' apply false
     id 'com.github.hierynomus.license' version '0.14.0' apply false
@@ -91,16 +90,30 @@ dependencies {
     implementation group: 'org.jetbrains', name: 'annotations', version: jetbrainsAnnotationsVersion
     implementation group: 'com.google.dagger', name: 'dagger', version: daggerVersion
 
-    implementation group: 'io.netty', name: 'netty-codec-http', version: nettyVersion, optional
-    implementation group: 'io.netty', name: 'netty-handler-proxy', version: nettyVersion, optional
-    implementation group: 'io.netty', name: 'netty-transport-native-epoll', version: nettyVersion, classifier: 'linux-x86_64', optional
-
     compileOnly group: 'org.slf4j', name: 'slf4j-api', version: slf4jVersion
 
     annotationProcessor group: 'com.google.dagger', name: 'dagger-compiler', version: daggerVersion
 }
 
 
+/* ******************** optional dependencies ******************** */
+
+def features = ['websocket', 'proxy', 'epoll']
+java {
+    features.each {
+        registerFeature(it) {
+            usingSourceSet(sourceSets.main)
+        }
+    }
+}
+
+dependencies {
+    websocketImplementation group: 'io.netty', name: 'netty-codec-http', version: nettyVersion
+    proxyImplementation group: 'io.netty', name: 'netty-handler-proxy', version: nettyVersion
+    epollImplementation group: 'io.netty', name: 'netty-transport-native-epoll', version: nettyVersion, classifier: 'linux-x86_64'
+}
+
+
 /* ******************** test ******************** */
 
 allprojects {
@@ -246,11 +259,12 @@ allprojects {
                             url = project.issuesUrl
                         }
                     }
-                    artifact javadocJar
-                    artifact sourcesJar
                 }
                 normal(MavenPublication) {
-                    from components.java
+                    from project.components.java
+                    artifact project.tasks.javadocJar
+                    artifact project.tasks.sourcesJar
+                    suppressAllPomMetadataWarnings()
                 }
             }
         }
@@ -286,6 +300,19 @@ allprojects {
                 }
             }
         }
+
+        // workaround for publishing gradle metadata https://github.com/bintray/gradle-bintray-plugin/issues/229
+        //noinspection UnnecessaryQualifiedReference
+        project.tasks.withType(com.jfrog.bintray.gradle.tasks.BintrayUploadTask) {
+            doFirst {
+                publishing.publications.withType(MavenPublication).each { publication ->
+                    def moduleFile = new File(new File(new File(project.buildDir, 'publications'), publication.name), 'module.json')
+                    if (moduleFile.exists()) {
+                        publication.artifact(moduleFile).setExtension('module')
+                    }
+                }
+            }
+        }
     }
 }
 
@@ -295,9 +322,11 @@ allprojects {
             publications {
                 shaded(MavenPublication) {
                     artifactId project.name + '-' + project.shadedAppendix
-                    artifact shadowJar
-                    pom.withXml { xml ->
-                        def dependenciesNode = xml.asNode().appendNode('dependencies')
+                    artifact project.tasks.shadowJar
+                    artifact project.tasks.javadocJar
+                    artifact project.tasks.sourcesJar
+                    pom.withXml {
+                        def dependenciesNode = asNode().appendNode('dependencies')
 
                         project.configurations.api.allDependencies.each {
                             def dependencyNode = dependenciesNode.appendNode('dependency')
@@ -313,6 +342,33 @@ allprojects {
     }
 }
 
+features.each { feature ->
+    publishing {
+        publications {
+            create(feature, MavenPublication) {
+                artifactId project.name + '-' + feature
+                pom.withXml {
+                    def dependenciesNode = asNode().appendNode('dependencies')
+
+                    def rootDependencyNode = dependenciesNode.appendNode('dependency')
+                    rootDependencyNode.appendNode('groupId', project.group)
+                    rootDependencyNode.appendNode('artifactId', project.name)
+                    rootDependencyNode.appendNode('version', project.version)
+                    rootDependencyNode.appendNode('scope', 'compile')
+
+                    project.configurations.getByName(feature + 'Implementation').allDependencies.each {
+                        def dependencyNode = dependenciesNode.appendNode('dependency')
+                        dependencyNode.appendNode('groupId', it.group)
+                        dependencyNode.appendNode('artifactId', it.name)
+                        dependencyNode.appendNode('version', it.version)
+                        dependencyNode.appendNode('scope', 'runtime')
+                    }
+                }
+            }
+        }
+    }
+}
+
 apply plugin: 'com.github.breadmoirai.github-release'
 
 githubRelease {

Diff for: gradle/wrapper/gradle-wrapper.properties

@@ -1,5 +1,5 @@
 #Wed Sep 25 23:53:09 CEST 2019
-distributionUrl=https\://services.gradle.org/distributions/gradle-5.6.2-all.zip
+distributionUrl=https\://services.gradle.org/distributions/gradle-6.1-all.zip
 distributionBase=GRADLE_USER_HOME
 distributionPath=wrapper/dists
 zipStorePath=wrapper/dists