highlight path separators

This commit is based on the work done by
Jorge Israel Peña (blaenk) in zsh-users#136.

Changes:
* Adjusted to changes on the latest master branch.
* Use regular path highlighter colors by default.
* Break out early if the separator color is the same to
  improve performance.
* Tests.

Author: m0vie

highlighters/main/main-highlighter.zsh

@@ -41,7 +41,9 @@
 : ${ZSH_HIGHLIGHT_STYLES[commandseparator]:=none}
 : ${ZSH_HIGHLIGHT_STYLES[hashed-command]:=fg=green}
 : ${ZSH_HIGHLIGHT_STYLES[path]:=underline}
+: ${ZSH_HIGHLIGHT_STYLES[path_pathseparator]:=${ZSH_HIGHLIGHT_STYLES[path_pathseparator]}}
 : ${ZSH_HIGHLIGHT_STYLES[path_prefix]:=underline}
+: ${ZSH_HIGHLIGHT_STYLES[path_prefix_pathseparator]:=${ZSH_HIGHLIGHT_STYLES[path_prefix_pathseparator]}}
 : ${ZSH_HIGHLIGHT_STYLES[globbing]:=fg=blue}
 : ${ZSH_HIGHLIGHT_STYLES[history-expansion]:=fg=blue}
 : ${ZSH_HIGHLIGHT_STYLES[single-hyphen-option]:=none}
@@ -517,7 +519,10 @@ _zsh_highlight_main_highlighter()
     fi
     # if a style_override was set (eg in _zsh_highlight_main_highlighter_check_path), use it
     [[ -n $style_override ]] && style=$style_override
-    (( already_added )) || _zsh_highlight_main_add_region_highlight $start_pos $end_pos $style
+    if ! (( already_added )); then
+      _zsh_highlight_main_add_region_highlight $start_pos $end_pos $style
+     [[ $style == path || $style == path_prefix ]] && _zsh_highlight_main_highlighter_highlight_path_separators
+    fi
     if [[ -n ${(M)ZSH_HIGHLIGHT_TOKENS_COMMANDSEPARATOR:#"$arg"} ]]; then
       next_word=':start:'
       highlight_glob=true
@@ -546,6 +551,18 @@ _zsh_highlight_main_highlighter_check_assign()
     [[ $arg == [[:alpha:]_][[:alnum:]_]#(|\[*\])(|[+])=* ]]
 }
 
+_zsh_highlight_main_highlighter_highlight_path_separators()
+{
+  local pos style_pathsep
+  style_pathsep=${style}_pathseparator
+  [[ -z "$ZSH_HIGHLIGHT_STYLES[$style_pathsep]" || "$ZSH_HIGHLIGHT_STYLES[$style]" == "$ZSH_HIGHLIGHT_STYLES[$style_pathsep]" ]] && return 0
+  for (( pos = start_pos; $pos <= end_pos; pos++ )) ; do
+    if [[ $BUFFER[pos+1] == / ]]; then
+      _zsh_highlight_main_add_region_highlight $pos $((pos + 1)) $style_pathsep
+    fi
+  done
+}
+
 # Check if $arg is a path.
 _zsh_highlight_main_highlighter_check_path()
 {

highlighters/main/test-data/path-separators.zsh

@@ -0,0 +1,49 @@
+# -------------------------------------------------------------------------------------------------
+# Copyright (c) 2015-2016 zsh-syntax-highlighting contributors
+# All rights reserved.
+#
+# Redistribution and use in source and binary forms, with or without modification, are permitted
+# provided that the following conditions are met:
+#
+#  * Redistributions of source code must retain the above copyright notice, this list of conditions
+#    and the following disclaimer.
+#  * Redistributions in binary form must reproduce the above copyright notice, this list of
+#    conditions and the following disclaimer in the documentation and/or other materials provided
+#    with the distribution.
+#  * Neither the name of the zsh-syntax-highlighting contributors nor the names of its contributors
+#    may be used to endorse or promote products derived from this software without specific prior
+#    written permission.
+#
+# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS OR
+# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND
+# FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR
+# CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
+# DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER
+# IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
+# OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+# -------------------------------------------------------------------------------------------------
+# -*- mode: zsh; sh-indentation: 2; indent-tabs-mode: nil; sh-basic-offset: 2; -*-
+# vim: ft=zsh sw=2 ts=2 et
+# -------------------------------------------------------------------------------------------------
+
+ZSH_HIGHLIGHT_TEST_ENABLE_PATH_SEPARATORS=1
+ZSH_HIGHLIGHT_STYLES[path_pathseparator]=unused
+ZSH_HIGHLIGHT_STYLES[path_prefix_pathseparator]=unused
+
+# Test assumes that '/bin/sh' exists and '/bin/s' does not exist.
+# Related to path_prefix2.zsh and path-separators.zsh
+
+mkdir A
+touch A/mu
+BUFFER='ls A/mu /bin/s'
+
+expected_region_highlight=(
+  "4 4 path"                           # A
+  "5 5 path_pathseparator"             # /
+  "6 7 path"                           # mu
+  "9 9 path_prefix_pathseparator"      # /
+  "10 12 path_prefix"                  # bin
+  "13 13 path_prefix_pathseparator"    # /
+  "14 14 path_prefix"                  # s
+)

highlighters/main/test-data/path_prefix2.zsh

@@ -28,7 +28,7 @@
 # -------------------------------------------------------------------------------------------------
 
 # Assumes that '/bin/sh' exists and '/bin/s' does not exist.
-# Related to path_prefix.zsh
+# Related to path_prefix.zsh and path-separators.zsh
 
 BUFFER='ls /bin/s'
 WIDGET=accept-line

tests/test-highlighting.zsh

@@ -53,9 +53,20 @@
 # Overwrite _zsh_highlight_add_highlight so we get the key itself instead of the style
 _zsh_highlight_add_highlight()
 {
-  region_highlight+=("$1 $2 $3")
+  local start="$1" end="$2" style="$3"
+
+  # Disable path separator highlighting unless requested otherwise.
+  (( ZSH_HIGHLIGHT_TEST_ENABLE_PATH_SEPARATORS )) || style=${style%_pathseparator}
+
+  region_highlight+=("$start $end $style")
 }
 
+# Disable path separator highlighting in tests by default.
+# Otherwise all tests using paths would need to be unnecessarily verbose.
+# Tests that actually test the separator handling should set
+# ZSH_HIGHLIGHT_TEST_ENABLE_PATH_SEPARATORS=1
+ZSH_HIGHLIGHT_TEST_ENABLE_PATH_SEPARATORS=0
+
 # Activate the highlighter.
 ZSH_HIGHLIGHT_HIGHLIGHTERS=($1)