Avoid CMOV with CFeq (#2571)

* CSEL special case for CFeq to avoid a jump for the unordered case

* Add a test

* Improve comment

Author: gretay-js

backend/amd64/selection.ml

@@ -346,6 +346,20 @@ method! select_operation op args dbg =
       Ispecific Izextend32, [arg]
     | _ -> super#select_operation op args dbg
     end
+  | Ccsel _ ->
+     begin match args with
+     | [cond; ifso; ifnot] ->
+       let (cond, earg) = self#select_condition cond in
+       (match cond with
+        | Ifloattest (w,CFeq) ->
+          (* CFeq cannot be represented as cmov without a jump.
+             CFneq emits cmov for "unordered" and "not equal" cases.
+             Use Cneq and swap the arguments. *)
+          Icsel (Ifloattest (w, CFneq)), [ earg; ifnot; ifso ]
+        | _ ->
+          (Icsel cond, [ earg; ifso; ifnot ]))
+     | _ -> super#select_operation op args dbg
+     end
   | Cprefetch { is_write; locality; } ->
       (* Emit prefetch for read hint when prefetchw is not supported.
          Matches the behavior of gcc's __builtin_prefetch *)

tests/intrinsics/dune

@@ -0,0 +1,5 @@
+(rule
+ (alias   runtest)
+ (enabled_if (= %{context_name} "main"))
+ (deps select_float.ml)
+ (action (run %{bin:ocamlopt.opt} %{deps} -c)))

tests/intrinsics/select_float.ml

@@ -0,0 +1,59 @@
+(* [AMD64] Special case of [caml_csel_value] with a float comparison
+   avoid branches for [equal].
+*)
+type t = float#
+
+module Float_u = struct
+  external to_float : float# -> (float[@local_opt]) = "%box_float"
+  external of_float : (float[@local_opt]) -> float# = "%unbox_float"
+
+  let[@inline] to_bits x = (Int64.bits_of_float) (to_float x)
+  let[@inline] of_bits x = (Int64.float_of_bits) x |> of_float
+
+  let[@inline always] div x y = of_float (Float.div (to_float x) (to_float y))
+
+  external select_int64
+    :  bool
+    -> (int64[@unboxed])
+    -> (int64[@unboxed])
+    -> (int64[@unboxed])
+    = "caml_csel_value" "caml_csel_int64_unboxed"
+  [@@noalloc] [@@no_effects] [@@no_coeffects] [@@builtin]
+
+  let[@inline] select b (ifso : t) (ifnot : t) : t =
+    select_int64 b (to_bits ifso) (to_bits ifnot) |> of_bits
+
+end
+
+external float_notequal : (float[@local_opt]) -> (float[@local_opt]) -> bool = "%notequal"
+external float_equal : (float[@local_opt]) -> (float[@local_opt]) -> bool = "%equal"
+
+
+let[@inline] divide_unless_denom_zero_else
+  ~(numer : float)
+  ~(denom : float)
+  ~(else_ : float)
+  =
+  let is_denom_zero = float_equal denom 0. in
+  let numer = Float_u.of_float numer in
+  let denom = Float_u.of_float denom in
+  let else_ = Float_u.of_float else_ in
+  Float_u.select
+    is_denom_zero
+    else_
+    (Float_u.div numer denom)
+  |> Float_u.to_float
+;;
+
+let is_result_larger_than_2
+  ~(numer : float)
+  ~(denom : float)
+  ~(else_ : float)
+  =
+  let result = divide_unless_denom_zero_else
+    ~numer
+    ~denom
+    ~else_
+  in
+  Float.compare result 2. > 0
+;;