Simplify Static_const.apply_renaming

Author: chambart

middle_end/flambda2/terms/static_const.ml

@@ -224,35 +224,19 @@ let apply_renaming t renaming =
       if or_var == or_var' then t else Boxed_nativeint or_var'
     | Mutable_string { initial_value = _ } | Immutable_string _ -> t
     | Immutable_float_block fields ->
-      let changed = ref false in
-      let fields =
-        List.map
-          (fun (field : _ Or_variable.t) ->
-            let field' : _ Or_variable.t =
-              match field with
-              | Var (v, dbg) -> Var (Renaming.apply_variable renaming v, dbg)
-              | Const _ -> field
-            in
-            if not (field == field') then changed := true;
-            field')
+      let fields' =
+        Misc.Stdlib.List.map_sharing
+          (fun field -> Or_variable.apply_renaming field renaming)
           fields
       in
-      if not !changed then t else Immutable_float_block fields
+      if fields == fields' then t else Immutable_float_block fields
     | Immutable_float_array fields ->
-      let changed = ref false in
-      let fields =
-        List.map
-          (fun (field : _ Or_variable.t) ->
-            let field' : _ Or_variable.t =
-              match field with
-              | Var (v, dbg) -> Var (Renaming.apply_variable renaming v, dbg)
-              | Const _ -> field
-            in
-            if not (field == field') then changed := true;
-            field')
+      let fields' =
+        Misc.Stdlib.List.map_sharing
+          (fun field -> Or_variable.apply_renaming field renaming)
           fields
       in
-      if not !changed then t else Immutable_float_array fields
+      if fields == fields' then t else Immutable_float_array fields
     | Empty_array -> Empty_array
 
 let all_ids_for_export t =

ocaml/utils/misc.ml

@@ -174,6 +174,17 @@ module Stdlib = struct
           }
       in
       find_prefix ~longest_common_prefix_rev:[] first second
+
+    let rec map_sharing f l =
+      match l with
+      | [] -> l
+      | h :: t ->
+        let new_t = map_sharing f t in
+        let new_h = f h in
+        if h == new_h && t == new_t then
+          l
+        else
+          new_h :: new_t
   end
 
   module Option = struct

ocaml/utils/misc.mli

@@ -138,6 +138,10 @@ module Stdlib : sig
     (** Returns the longest list that, with respect to the provided equality
         function, is a prefix of both of the given lists.  The input lists,
         each with such longest common prefix removed, are also returned. *)
+
+    val map_sharing : ('a -> 'a) -> 'a list -> 'a list
+    (** [map_sharing f l] is [List.map f l].
+        If for each [x] in [l], [f x == x] then [map_sharing f l == l] *)
   end
 
   module Option : sig