build.gradle

plugins {
	id 'java'
	alias(libs.plugins.spring.boot)
	alias(libs.plugins.spring.dep.mgmt)
}

description = 'Spring Pulsar Sample (Custom Routing w/ Failover)'

repositories {
	mavenCentral()
	maven { url 'https://repo.spring.io/milestone' }
	maven { url 'https://repo.spring.io/snapshot' }
}

def versionCatalog = extensions.getByType(VersionCatalogsExtension).named("libs")
def pulsarVersion = versionCatalog.findVersion("pulsar").orElseThrow().displayName

ext['spring-pulsar.version'] = "${project.property('version.samples')}"
ext['pulsar.version'] = "${pulsarVersion}"

dependencies {
	implementation 'org.springframework.boot:spring-boot-starter-pulsar'
	implementation 'org.springframework.boot:spring-boot-starter-actuator'
// TODO add back in once samples are not run during part of the 'test' target
//	implementation 'io.micrometer:micrometer-tracing-bridge-brave'
//	implementation 'io.zipkin.reporter2:zipkin-reporter-brave'
//	implementation 'io.zipkin.reporter2:zipkin-sender-urlconnection'
	developmentOnly 'org.springframework.boot:spring-boot-docker-compose'

	testImplementation project(':spring-pulsar-test')
	testRuntimeOnly 'ch.qos.logback:logback-classic'
	testImplementation "org.springframework.boot:spring-boot-starter-test"
	testImplementation "org.springframework.boot:spring-boot-testcontainers"
	testImplementation 'org.testcontainers:junit-jupiter'
	testImplementation 'org.testcontainers:pulsar'
}

test {
	useJUnitPlatform()
	testLogging.showStandardStreams = true
	outputs.upToDateWhen { false }
}

bootRun {
	jvmArgs = [
			"--add-opens", "java.base/java.lang=ALL-UNNAMED",
			"--add-opens", "java.base/java.util=ALL-UNNAMED",
			"--add-opens", "java.base/sun.net=ALL-UNNAMED"
	]
	// when run from command line, path must be set relative to module dir
	systemProperty 'spring.docker.compose.file', 'compose.yaml'
}