Mark RAM node type as deprecated

dumbbell · dumbbell · commit b8b5bb936e01 · 2023-07-05T11:09:24.000+02:00
[Why] RAM nodes provide no safety at all and they lost interest with recent fast storage solutions. [How] RAM nodes are marked as deprecated in the code using the Deprecated features subsystem (based on feature flags). See pull request #7390 for a description of that subsystem. To test RabbitMQ behavior as if the feature was removed, the following configuration setting can be used: deprecated_features.permit.ram_node_type = false To turn off RAM nodes, there must be no RAM nodes in the cluster. Once RAM nodes are turned off, an existing node previously created as a RAM node will change itself to a disc node during boot. If a new node is added to the cluster using peer discovery or the CLI, it will be as a disc node and a warning will be logged if the requested node type is RAM. Note that given the marketing calendar, the deprecated feature will go directly from "permitted by default" to "removed" in RabbitMQ 4.0. It won't go through the gradual deprecation process.
diff --git a/deps/rabbit/src/rabbit_mnesia.erl b/deps/rabbit/src/rabbit_mnesia.erl
@@ -79,6 +79,12 @@
 %% Main interface
 %%----------------------------------------------------------------------------
 
+-rabbit_deprecated_feature(
+   {ram_node_type,
+    #{deprecation_phase => permitted_by_default,
+      doc_url => "https://blog.rabbitmq.com/posts/2021/08/4.0-deprecation-announcements/#removal-of-ram-nodes"
+     }}).
+
 -spec init() -> 'ok'.
 
 init() ->
@@ -94,8 +100,18 @@ init() ->
             init_with_lock();
         false ->
             NodeType = node_type(),
-            init_db_and_upgrade(cluster_nodes(all), NodeType,
-                                NodeType =:= ram, _Retry = true),
+            NodeTypeConvNeeded = not is_node_type_permitted(NodeType),
+            case NodeTypeConvNeeded of
+                false ->
+                    init_db_and_upgrade(cluster_nodes(all), NodeType,
+                                        NodeType =:= ram, _Retry = true);
+                true ->
+                    rabbit_log:info(
+                      "RAM nodes are deprecated and not permitted. This "
+                      "node will be converted to a disc node."),
+                    init_db_and_upgrade(cluster_nodes(all), disc,
+                                        true, _Retry = true)
+            end,
             rabbit_peer_discovery:maybe_init(),
             rabbit_peer_discovery:maybe_register()
     end,
@@ -180,9 +196,13 @@ run_peer_discovery_with_retries(RetriesLeft, DelayInterval) ->
                             "Enabling debug logging might help troubleshoot."),
             init_db_and_upgrade([node()], disc, false, _Retry = true);
         _  ->
+            NodeType1 = case is_node_type_permitted(NodeType) of
+                            false -> disc;
+                            true  -> NodeType
+                        end,
             rabbit_log:info("Peer nodes we can cluster with: ~ts",
                 [rabbit_peer_discovery:format_discovered_nodes(Peers)]),
-            join_discovered_peers(Peers, NodeType)
+            join_discovered_peers(Peers, NodeType1)
     end.
 
 %% Attempts to join discovered,
@@ -250,10 +270,15 @@ join_cluster(DiscoveryNode, NodeType) ->
                     %% of resetting the node from the user.
                     reset_gracefully(),
 
+                    NodeType1 = case is_node_type_permitted(NodeType) of
+                                    false -> disc;
+                                    true  -> NodeType
+                                end,
+
                     %% Join the cluster
                     rabbit_log:info("Clustering with ~tp as ~tp node",
-                                    [ClusterNodes, NodeType]),
-                    ok = init_db_with_mnesia(ClusterNodes, NodeType,
+                                    [ClusterNodes, NodeType1]),
+                    ok = init_db_with_mnesia(ClusterNodes, NodeType1,
                                              true, true, _Retry = true),
                     rabbit_node_monitor:notify_joined_cluster(),
                     ok;
@@ -320,6 +345,7 @@ wipe() ->
 -spec change_cluster_node_type(rabbit_db_cluster:node_type()) -> 'ok'.
 
 change_cluster_node_type(Type) ->
+    ensure_node_type_is_permitted(Type),
     ensure_mnesia_not_running(),
     ensure_mnesia_dir(),
     case is_clustered() of
@@ -549,6 +575,20 @@ node_type() ->
         false -> ram
     end.
 
+is_node_type_permitted(ram) ->
+    rabbit_deprecated_features:is_permitted(ram_node_type);
+is_node_type_permitted(_NodeType) ->
+    true.
+
+ensure_node_type_is_permitted(NodeType) ->
+    case is_node_type_permitted(NodeType) of
+        true ->
+            ok;
+        false ->
+            Warning = rabbit_deprecated_features:get_warning(ram_node_type),
+            throw({error, Warning})
+    end.
+
 -spec dir() -> file:filename().
 
 dir() -> mnesia:system_info(directory).
@@ -562,6 +602,8 @@ dir() -> mnesia:system_info(directory).
 %% nodes in the cluster already. It also updates the cluster status
 %% file.
 init_db(ClusterNodes, NodeType, CheckOtherNodes) ->
+    ensure_node_type_is_permitted(NodeType),
+
     NodeIsVirgin = is_virgin_node(),
     rabbit_log:debug("Does data directory looks like that of a blank (uninitialised) node? ~tp", [NodeIsVirgin]),
     %% We want to synchronize feature flags first before we wait for
diff --git a/deps/rabbit/test/rabbitmq_4_0_deprecations_SUITE.erl b/deps/rabbit/test/rabbitmq_4_0_deprecations_SUITE.erl
@@ -23,22 +23,29 @@
          end_per_testcase/2,
 
          when_global_qos_is_permitted_by_default/1,
-         when_global_qos_is_not_permitted_from_conf/1
+         when_global_qos_is_not_permitted_from_conf/1,
+
+         join_when_ram_node_type_is_permitted_by_default/1,
+         join_when_ram_node_type_is_not_permitted_from_conf/1
         ]).
 
 suite() ->
     [{timetrap, {minutes, 5}}].
 
 all() ->
     [
-     {group, global_qos}
+     {group, global_qos},
+     {group, ram_node_type}
     ].
 
 groups() ->
     [
      {global_qos, [],
       [when_global_qos_is_permitted_by_default,
-       when_global_qos_is_not_permitted_from_conf]}
+       when_global_qos_is_not_permitted_from_conf]},
+     {ram_node_type, [],
+      [join_when_ram_node_type_is_permitted_by_default,
+       join_when_ram_node_type_is_not_permitted_from_conf]}
     ].
 
 %% -------------------------------------------------------------------
@@ -57,6 +64,9 @@ end_per_suite(Config) ->
 
 init_per_group(global_qos, Config) ->
     rabbit_ct_helpers:set_config(Config, {rmq_nodes_count, 1});
+init_per_group(ram_node_type, Config) ->
+    rabbit_ct_helpers:set_config(Config, [{rmq_nodes_count, 2},
+                                          {rmq_nodes_clustered, false}]);
 init_per_group(_Group, Config) ->
     Config.
 
@@ -70,6 +80,13 @@ init_per_testcase(
                 {rabbit,
                  [{permit_deprecated_features, #{global_qos => false}}]}),
     init_per_testcase1(Testcase, Config1);
+init_per_testcase(
+  join_when_ram_node_type_is_not_permitted_from_conf = Testcase, Config) ->
+    Config1 = rabbit_ct_helpers:merge_app_env(
+                Config,
+                {rabbit,
+                 [{permit_deprecated_features, #{ram_node_type => false}}]}),
+    init_per_testcase1(Testcase, Config1);
 init_per_testcase(Testcase, Config) ->
     init_per_testcase1(Testcase, Config).
 
@@ -152,6 +169,95 @@ is_prefetch_limited(ServerCh) ->
     LimiterState = element(3, ChState),
     element(3, LimiterState).
 
+%% -------------------------------------------------------------------
+%% RAM node type.
+%% -------------------------------------------------------------------
+
+join_when_ram_node_type_is_permitted_by_default(Config) ->
+    [NodeA, NodeB] = rabbit_ct_broker_helpers:get_node_configs(
+                       Config, nodename),
+
+    ok = rabbit_control_helper:command(stop_app, NodeA),
+    ok = rabbit_control_helper:command_with_output(
+           join_cluster, NodeA,
+           [atom_to_list(NodeB)], [{"--ram", true}]),
+    ok = rabbit_control_helper:command(start_app, NodeA),
+
+    ?assertEqual([NodeA, NodeB], get_all_nodes(Config, NodeA)),
+    ?assertEqual([NodeA, NodeB], get_all_nodes(Config, NodeB)),
+    ?assertEqual([NodeB], get_disc_nodes(Config, NodeA)),
+    ?assertEqual([NodeB], get_disc_nodes(Config, NodeB)),
+
+    ?assert(
+       log_file_contains_message(
+         Config, NodeA,
+         ["Deprecated features: `ram_node_type`: Feature `ram_node_type` is deprecated",
+          "By default, this feature can still be used for now."])),
+
+    %% Change the advanced configuration file to turn off RAM node type.
+    ConfigFilename0 = rabbit_ct_broker_helpers:get_node_config(
+                        Config, NodeA, erlang_node_config_filename),
+    ConfigFilename = ConfigFilename0 ++ ".config",
+    {ok, [ConfigContent0]} = file:consult(ConfigFilename),
+    ConfigContent1 = rabbit_ct_helpers:merge_app_env_in_erlconf(
+                       ConfigContent0,
+                       {rabbit, [{permit_deprecated_features,
+                                  #{ram_node_type => false}}]}),
+    ConfigContent2 = lists:flatten(io_lib:format("~p.~n", [ConfigContent1])),
+    ok = file:write_file(ConfigFilename, ConfigContent2),
+    ?assertEqual({ok, [ConfigContent1]}, file:consult(ConfigFilename)),
+
+    %% Restart the node and see if it was correctly converted to a disc node.
+    ok = rabbit_control_helper:command(stop_app, NodeA),
+    Ret = rabbit_control_helper:command(start_app, NodeA),
+
+    case Ret of
+        ok ->
+            ?assertEqual([NodeA, NodeB], get_all_nodes(Config, NodeA)),
+            ?assertEqual([NodeA, NodeB], get_all_nodes(Config, NodeB)),
+            ?assertEqual([NodeA, NodeB], get_disc_nodes(Config, NodeA)),
+            ?assertEqual([NodeA, NodeB], get_disc_nodes(Config, NodeB));
+        {error, 69,
+         <<"Error:\n{:rabbit, {:incompatible_feature_flags, ", _/binary>>} ->
+            {skip, "Incompatible feature flags between nodes A and B"}
+    end.
+
+join_when_ram_node_type_is_not_permitted_from_conf(Config) ->
+    [NodeA, NodeB] = rabbit_ct_broker_helpers:get_node_configs(
+                       Config, nodename),
+
+    ok = rabbit_control_helper:command(stop_app, NodeA),
+    Ret = rabbit_control_helper:command_with_output(
+            join_cluster, NodeA,
+            [atom_to_list(NodeB)], [{"--ram", true}]),
+    case Ret of
+        ok ->
+            ok = rabbit_control_helper:command(start_app, NodeA),
+
+            ?assertEqual([NodeA, NodeB], get_all_nodes(Config, NodeA)),
+            ?assertEqual([NodeA, NodeB], get_all_nodes(Config, NodeB)),
+            ?assertEqual([NodeA, NodeB], get_disc_nodes(Config, NodeA)),
+            ?assertEqual([NodeA, NodeB], get_disc_nodes(Config, NodeB)),
+
+            ?assert(
+               log_file_contains_message(
+                 Config, NodeA,
+                 ["Deprecated features: `ram_node_type`: Feature `ram_node_type` is deprecated",
+                  "Its use is not permitted per the configuration"]));
+        {error, 69, <<"Error:\nincompatible_feature_flags">>} ->
+            {skip, "Incompatible feature flags between nodes A and B"}
+    end.
+
+get_all_nodes(Config, Node) ->
+    lists:sort(
+      rabbit_ct_broker_helpers:rpc(
+        Config, Node, rabbit_mnesia, cluster_nodes, [all])).
+
+get_disc_nodes(Config, Node) ->
+    lists:sort(
+      rabbit_ct_broker_helpers:rpc(
+        Config, Node, rabbit_mnesia, cluster_nodes, [disc])).
+
 %% -------------------------------------------------------------------
 %% Helpers.
 %% -------------------------------------------------------------------
