title	description	canonical
Function	Function syntax in ReScript	/docs/manual/latest/function

Function

Cheat sheet for the full function syntax at the end.

ReScript functions are declared with an arrow and return an expression, just like JS functions. They compile to clean JS functions too.

let greet = (name) => "Hello " ++ name

function greet(name) {
  return "Hello " + name;
}

This declares a function and assigns to it the name greet, which you can call like so:

greet("world!") // "Hello world!"

greet("world!");

Multi-arguments functions have arguments separated by comma:

let add = (x, y, z) => x + y + z
add(1, 2, 3) // 6

function add(x, y, z) {
  return (x + y | 0) + z | 0;
}

For longer functions, you'd surround the body with a block:

let greetMore = (name) => {
  let part1 = "Hello"
  part1 ++ " " ++ name
}

function greetMore(name) {
  return "Hello " + name;
}

If your function has no argument, just write let greetMore = () => {...}.

Labeled Arguments

Multi-arguments functions, especially those whose arguments are of the same type, can be confusing to call.

let addCoordinates = (x, y) => {
  // use x and y here
}
// ...
addCoordinates(5, 6) // which is x, which is y?

function addCoordinates(x, y) {
  // use x and y here
}

addCoordinates(5, 6);

You can attach labels to an argument by prefixing the name with the ~ symbol:

let addCoordinates = (~x, ~y) => {
  // use x and y here
}
// ...
addCoordinates(~x=5, ~y=6)

function addCoordinates(x, y) {
  // use x and y here
}

addCoordinates(5, 6);

You can provide the arguments in any order:

addCoordinates(~y=6, ~x=5)

addCoordinates(5, 6);

The ~x part in the declaration means the function accepts an argument labeled x and can refer to it in the function body by the same name. You can also refer to the arguments inside the function body by a different name for conciseness:

let drawCircle = (~radius as r, ~color as c) => {
  setColor(c)
  startAt(r, r)
  // ...
}

drawCircle(~radius=10, ~color="red")

function drawCircle(r, c) {
  setColor(c);
  return startAt(r, r);
}

drawCircle(10, "red");

As a matter of fact, (~radius) is just a shorthand for (~radius as radius).

Here's the syntax for typing the arguments:

let drawCircle = (~radius as r: int, ~color as c: string) => {
  // code here
}

function drawCircle(r, c) {
  // code here
}

Optional Labeled Arguments

Labeled function arguments can be made optional during declaration. You can then omit them when calling the function.

// radius can be omitted
let drawCircle = (~color, ~radius=?) => {
  setColor(color)
  switch radius {
  | None => startAt(1, 1)
  | Some(r_) => startAt(r_, r_)
  }
}

var Caml_option = require("./stdlib/caml_option.js");

function drawCircle(color, radius) {
  setColor(color);
  if (radius === undefined) {
    return startAt(1, 1);
  }
  var r_ = Caml_option.valFromOption(radius);
  return startAt(r_, r_);
}

When given in this syntax, radius is wrapped in the standard library's option type, defaulting to None. If provided, it'll be wrapped with a Some. So radius's type value is None | Some(int) here.

Signatures and Type Annotations

Functions with optional labeled arguments can be confusing when it comes to signature and type annotations. Indeed, the type of an optional labeled argument looks different depending on whether you're calling the function, or working inside the function body. Outside the function, a raw value is either passed in (int, for example), or left off entirely. Inside the function, the parameter is always there, but its value is an option (option<int>). This means that the type signature is different, depending on whether you're writing out the function type, or the parameter type annotation. The first being a raw value, and the second being an option.

If we get back to our previous example and both add a signature and type annotations to its argument, we get this:

let drawCircle: (~color: color, ~radius: int=?) => unit =
  (~color: color, ~radius: option<int>=?) => {
    setColor(color)
    switch radius {
    | None => startAt(1, 1)
    | Some(r_) => startAt(r_, r_)
    }
  }

function drawCircle(color, radius) {
  setColor(color);
  if (radius !== undefined) {
    return startAt(radius, radius);
  } else {
    return startAt(1, 1);
  }
}

The first line is the function's signature, we would define it like that in an interface file (see Signatures). The function's signature describes the types that the outside world interacts with, hence the type int for radius because it indeed expects an int when called.

In the second line, we annotate the arguments to help us remember the types of the arguments when we use them inside the function's body, here indeed radius will be an option<int> inside the function.

So if you happen to struggle when writing the signature of a function with optional labeled arguments, try to remember this!

Explicitly Passed Optional

Sometimes, you might want to forward a value to a function without knowing whether the value is None or Some(a). Naively, you'd do:

let result =
  switch payloadRadius {
  | None => drawCircle(~color)
  | Some(r) => drawCircle(~color, ~radius=r)
  }

var r = payloadRadius;

var result = r !== undefined
  ? drawCircle(color, Caml_option.valFromOption(r))
  : drawCircle(color);

This quickly gets tedious. We provide a shortcut:

let result = drawCircle(~color, ~radius=?payloadRadius)

var result = drawCircle(1, undefined);

This means "I understand radius is optional, and that when I pass it a value it needs to be an int, but I don't know whether the value I'm passing is None or Some(val), so I'll pass you the whole option wrapper".

Optional with Default Value

Optional labeled arguments can also be provided a default value. In this case, they aren't wrapped in an option type.

let drawCircle = (~radius=1, ~color) => {
  setColor(color)
  startAt(radius, radius)
}

function drawCircle(radiusOpt, color) {
  var radius = radiusOpt !== undefined ? radiusOpt : 1;
  setColor(color);
  return startAt(radius, radius);
}

Recursive Functions

ReScript chooses the sane default of preventing a function to be called recursively within itself. To make a function recursive, add the rec keyword after the let:

let rec neverTerminate = () => neverTerminate()

function neverTerminate(_param) {
  while(true) {
    _param = undefined;
    continue ;
  };
}

A simple recursive function may look like this:

// Recursively check every item on the list until one equals the `item`
// argument. If a match is found, return `true`, otherwise return `false`
let rec listHas = (list, item) =>
  switch list {
  | list{} => false
  | list{a, ...rest} => a === item || listHas(rest, item)
  }

function listHas(_list, item) {
  while(true) {
    var list = _list;
    if (!list) {
      return false;
    }
    if (list.hd === item) {
      return true;
    }
    _list = list.tl;
    continue ;
  };
}

Recursively calling a function is bad for performance and the call stack. However, ReScript intelligently compiles tail recursion into a fast JavaScript loop. Try checking the JS output of the above code!

Mutually Recursive Functions

Mutually recursive functions start like a single recursive function using the rec keyword, and then are chained together with and:

let rec callSecond = () => callFirst()
and callFirst = () => callSecond()

function callSecond(_param) {
  while(true) {
    _param = undefined;
    continue ;
  };
}

function callFirst(_param) {
  while(true) {
    _param = undefined;
    continue ;
  };
}

Partial Application

Since 11.0

To partially apply a function, use the explicit ... syntax.

let add = (a, b) => a + b
let addFive = add(5, ...)

function add(a, b) {
  return a + b | 0;
}

function addFive(extra) {
  return 5 + extra | 0;
}

Async/Await

Just as in JS, an async function can be declared by adding async before the definition, and await can be used in the body of such functions. The output looks like idiomatic JS:

let getUserName = async (userId) => userId

let greetUser = async (userId) => {
  let name = await getUserName(userId)  
  "Hello " ++ name ++ "!"
}

async function greetUser(userId) {
  var name = await getUserName(userId);
  return "Hello " + name + "!";
}

The return type of getUser is inferred to be promise<string>. Similarly, await getUserName(userId) returns a string when the function returns promise<string>. Using await outside of an async function (including in a non-async callback to an async function) is an error.

Ergonomic error handling

Error handling is done by simply using try/catch, or a switch with an exception case, just as in functions that are not async. Both JS exceptions and exceptions defined in ReScript can be caught. The compiler takes care of packaging JS exceptions into the builtin JsError exception:

exception SomeReScriptException

let somethingThatMightThrow = async () => raise(SomeReScriptException)

let someAsyncFn = async () => {
  switch await somethingThatMightThrow() {
  | data => Some(data)
  | exception JsError(_) => None
  | exception SomeReScriptException => None
  }
}

var SomeReScriptException = /* @__PURE__ */Caml_exceptions.create("Example.SomeReScriptException");

async function someAsyncFn(param) {
  var data;
  try {
    data = await somethingThatMightThrow(undefined);
  }
  catch (raw_exn){
    var exn = Caml_js_exceptions.internalToOCamlException(raw_exn);
    if (exn.RE_EXN_ID === "JsError") {
      return ;
    }
    if (exn.RE_EXN_ID === SomeReScriptException) {
      return ;
    }
    throw exn;
  }
  return data;
}

The ignore() Function

Occasionally you may want to ignore the return value of a function. ReScript provides an ignore() function that discards the value of its argument and returns ():

mySideEffect()->Promise.catch(handleError)->ignore

Js.Global.setTimeout(myFunc, 1000)->ignore

$$Promise.$$catch(mySideEffect(), function (prim) {
  return handleError(prim);
});

setTimeout(function (prim) {
  myFunc();
}, 1000);

Tips & Tricks

Cheat sheet for the function syntaxes:

Declaration

// anonymous function
(x, y) => 1
// bind to a name
let add = (x, y) => 1

// labeled
let add = (~first as x, ~second as y) => x + y
// with punning sugar
let add = (~first, ~second) => first + second

// labeled with default value
let add = (~first as x=1, ~second as y=2) => x + y
// with punning
let add = (~first=1, ~second=2) => first + second

// optional
let add = (~first as x=?, ~second as y=?) => switch x {...}
// with punning
let add = (~first=?, ~second=?) => switch first {...}

With Type Annotation

// anonymous function
(x: int, y: int): int => 1
// bind to a name
let add = (x: int, y: int): int => 1

// labeled
let add = (~first as x: int, ~second as y: int) : int => x + y
// with punning sugar
let add = (~first: int, ~second: int) : int => first + second

// labeled with default value
let add = (~first as x: int=1, ~second as y: int=2) : int => x + y
// with punning sugar
let add = (~first: int=1, ~second: int=2) : int => first + second

// optional
let add = (~first as x: option<int>=?, ~second as y: option<int>=?) : int => switch x {...}
// with punning sugar
// note that the caller would pass an `int`, not `option<int>`
// Inside the function, `first` and `second` are `option<int>`.
let add = (~first: option<int>=?, ~second: option<int>=?) : int => switch first {...}

Application

add(x, y)

// labeled
add(~first=1, ~second=2)
// with punning sugar
add(~first, ~second)

// application with default value. Same as normal application
add(~first=1, ~second=2)

// explicit optional application
add(~first=?Some(1), ~second=?Some(2))
// with punning
add(~first?, ~second?)

With Type Annotation

// labeled
add(~first=1: int, ~second=2: int)
// with punning sugar
add(~first: int, ~second: int)

// application with default value. Same as normal application
add(~first=1: int, ~second=2: int)

// explicit optional application
add(~first=?Some(1): option<int>, ~second=?Some(2): option<int>)
// no punning sugar when you want to type annotate

Standalone Type Signature

// first arg type, second arg type, return type
type add = (int, int) => int

// labeled
type add = (~first: int, ~second: int) => int

// labeled
type add = (~first: int=?, ~second: int=?, unit) => int

In Interface Files

To annotate a function from the implementation file (.res) in your interface file (.resi):

let add: (int, int) => int

The type annotation part is the same as the previous section on With Type Annotation.

Don't confuse let add: myType with type add = myType. When used in .resi interface files, the former exports the binding add while annotating it as type myType. The latter exports the type add, whose value is the type myType.

Provide feedback

Saved searches

Use saved searches to filter your results more quickly

function.mdx

function.mdx

Function

Labeled Arguments

Optional Labeled Arguments

Signatures and Type Annotations

Explicitly Passed Optional

Optional with Default Value

Recursive Functions

Mutually Recursive Functions

Partial Application

Async/Await

Ergonomic error handling

The ignore() Function

Tips & Tricks

Declaration

With Type Annotation

Application

With Type Annotation

Standalone Type Signature

In Interface Files

Files

function.mdx

Latest commit

History

function.mdx

File metadata and controls

Function

Labeled Arguments

Optional Labeled Arguments

Signatures and Type Annotations

Explicitly Passed Optional

Optional with Default Value

Recursive Functions

Mutually Recursive Functions

Partial Application

Async/Await

Ergonomic error handling

The ignore() Function

Tips & Tricks

Declaration

With Type Annotation

Application

With Type Annotation

Standalone Type Signature

In Interface Files