Add LanguageClient#openHoverInSeparateWindow()

to reopen floating hover in separate preview window

Author: rhysd

autoload/LanguageClient.vim

@@ -273,7 +273,7 @@ function! s:CloseFloatingHoverOnCursorMove(win_id, opened) abort
         " was really moved
         return
     endif
-    autocmd! plugin-LC-neovim-close-hover
+    silent! autocmd! plugin-LC-neovim-close-hover
     let winnr = win_id2win(a:win_id)
     if winnr == 0
         return
@@ -285,7 +285,7 @@ function! s:CloseFloatingHoverOnBufEnter(win_id, bufnr) abort
     let winnr = win_id2win(a:win_id)
     if winnr == 0
         " Float window was already closed
-        autocmd! plugin-LC-neovim-close-hover
+        silent! autocmd! plugin-LC-neovim-close-hover
         return
     endif
     if winnr == winnr()
@@ -296,7 +296,7 @@ function! s:CloseFloatingHoverOnBufEnter(win_id, bufnr) abort
         " When current buffer opened hover window, it's not another buffer. Skipped
         return
     endif
-    autocmd! plugin-LC-neovim-close-hover
+    silent! autocmd! plugin-LC-neovim-close-hover
     execute winnr . 'wincmd c'
 endfunction
 
@@ -388,17 +388,22 @@ function! s:OpenHoverPreview(bufname, lines, filetype) abort
     endif
 endfunction
 
-function! s:MoveIntoHoverPreview() abort
+function! s:GetHoverPreviewBufnr() abort
     for bufnr in range(1, bufnr('$'))
         if bufname(bufnr) ==# '__LanguageClient__'
-            let winnr = bufwinnr(bufnr)
-            if winnr != -1
-                execute winnr . 'wincmd w'
-            endif
-            return v:true
+            return bufnr
         endif
     endfor
-    return v:false
+    return -1
+endfunction
+
+function! s:MoveIntoHoverPreview() abort
+    let winnr = bufwinnr(s:GetHoverPreviewBufnr())
+    if winnr == -1
+        return v:false
+    endif
+    execute winnr . 'wincmd w'
+    return v:true
 endfunction
 
 let s:id = 1
@@ -1294,4 +1299,30 @@ function! LanguageClient#debugInfo(...) abort
     return LanguageClient#Call('languageClient/debugInfo', l:params, l:Callback)
 endfunction
 
+function! LanguageClient#openHoverInSeparateWindow() abort
+    let bufnr = s:GetHoverPreviewBufnr()
+    if bufnr == -1
+        echo 'No hover found'
+        return
+    endif
+
+    let lines = nvim_buf_get_lines(bufnr, 1, -1, v:false)
+    let filetype = nvim_buf_get_option(bufnr, 'filetype')
+    let name = bufname(bufnr)
+
+    silent! autocmd! plugin-LC-neovim-close-hover
+    let winnr = bufwinnr(bufnr)
+    if winnr != -1
+        execute winnr . 'wincmd c'
+    endif
+
+    execute 'silent! noswapfile pedit!' name
+    wincmd P
+    setlocal buftype=nofile nobuflisted bufhidden=wipe nonumber norelativenumber signcolumn=no
+    let &filetype = filetype
+    call setline(1, lines)
+    setlocal nomodified nomodifiable
+    wincmd p
+endfunction
+
 let g:LanguageClient_loaded = s:Launch()

doc/LanguageClient.txt

@@ -633,6 +633,13 @@ Signature: LanguageClient#debugInfo(...)
 
 Print out debug info.
 
+*LanguageClient#openHoverInSeparateWindow*
+Signature: LanguageClient#openHoverInSeparateWindow()
+
+When a hover is open in floating window, calling this function reopens the
+content in a separate preview window. This function is useful when you want to
+keep it open.
+
 ==============================================================================
 5. Events                                               *LanguageClientEvents*
 

tests/LanguageClient_test.py

@@ -333,3 +333,29 @@ def test_textDocument_hover_float_window_move_cursor_into_window(nvim):
     # Check float window buffer was closed by :close in the window
     assert all(
         b for b in nvim.buffers if not b.name.endswith("__LanguageClient__"))
+
+
+def test_textDocument_hover_float_window_reopen_in_preview_window(nvim):
+    if not nvim.funcs.exists("*nvim_open_win"):
+        pytest.skip("Neovim 0.3.0 or earlier does not support floating window")
+
+    nvim.command("edit! {}".format(PATH_INDEXJS))
+    time.sleep(1)
+
+    _open_float_window(nvim)
+
+    try:
+        nvim.call("LanguageClient#openHoverInSeparateWindow")
+        preview_buf = next(
+            b for b in nvim.buffers if b.name.endswith("__LanguageClient__"))
+
+        winnr = nvim.funcs.bufwinnr(preview_buf.number)
+        assert winnr > 0
+
+        win_id = nvim.funcs.win_getid(winnr)
+        assert win_id > 0
+
+        assert nvim.api.win_get_option(win_id, 'previewwindow') == 1
+        assert nvim.api.buf_get_option(preview_buf, 'filetype') == 'markdown'
+    finally:
+        nvim.api.win_close(win_id, True)