Add new 'auto_format_git_diff' behavior

When you edit a file tracked in git, it may happend that some tracked
lines are not well formatted. If you modify this file, and you
auto_format the file, lines with bad indentation will be formatted too.
You will be end up with unrelated changes in your commit.

It may even appear that these 'bad formatted lines' were indented like
this with a purpose.

To mitigate this issue, this commit proposes to only format diff'ed
lines in a file. It roughly relies on git diff, and on clang-format
'-lines' option.

clang_format#format function has been modified to accept a list of
ranges.

It adds three new user options:
- g:clang_format#auto_format_git_diff to enable this new behavior
- g:clang_format#auto_format_git_diff_fallback to decide what to do in
  case of untracked file
- g:clang_format#git to define non standard git path or options

Author: jerome

autoload/clang_format.vim

@@ -139,6 +139,14 @@ function! clang_format#is_invalid() abort
         let s:version = v
     endif
 
+    if g:clang_format#auto_format_git_diff &&
+                \ !exists('s:git_available')
+        if !executable(g:clang_format#git)
+            return 1
+        endif
+        let s:git_available = 1
+    endif
+
     return 0
 endfunction
 
@@ -184,6 +192,7 @@ let g:clang_format#extra_args = s:getg('clang_format#extra_args', "")
 if type(g:clang_format#extra_args) == type([])
     let g:clang_format#extra_args = join(g:clang_format#extra_args, " ")
 endif
+let g:clang_format#git = s:getg('clang_format#git', 'git')
 
 let g:clang_format#code_style = s:getg('clang_format#code_style', 'google')
 let g:clang_format#style_options = s:getg('clang_format#style_options', {})
@@ -193,6 +202,8 @@ let g:clang_format#detect_style_file = s:getg('clang_format#detect_style_file',
 let g:clang_format#enable_fallback_style = s:getg('clang_format#enable_fallback_style', 1)
 
 let g:clang_format#auto_format = s:getg('clang_format#auto_format', 0)
+let g:clang_format#auto_format_git_diff = s:get('clang_format#auto_format_git_diff', 0)
+let g:clang_format#auto_format_git_diff_fallback = s:get('clang_format#auto_format_git_diff_fallback', 'file')
 let g:clang_format#auto_format_on_insert_leave = s:getg('clang_format#auto_format_on_insert_leave', 0)
 let g:clang_format#auto_formatexpr = s:getg('clang_format#auto_formatexpr', 0)
 " }}}
@@ -203,8 +214,11 @@ function! s:detect_style_file() abort
     return findfile('.clang-format', dirname.';') != '' || findfile('_clang-format', dirname.';') != ''
 endfunction
 
-function! clang_format#format(line1, line2) abort
-    let args = printf(' -lines=%d:%d', a:line1, a:line2)
+function! clang_format#format(ranges) abort
+    let args = ''
+    for range in a:ranges
+        let args .= printf(' -lines=%d:%d', range[0], range[1])
+    endfor
     if ! (g:clang_format#detect_style_file && s:detect_style_file())
         if g:clang_format#enable_fallback_style
             let args .= ' ' . s:shellescape(printf('-style=%s', s:make_style_options())) . ' '
@@ -226,11 +240,11 @@ endfunction
 " }}}
 
 " replace buffer {{{
-function! clang_format#replace(line1, line2, ...) abort
+function! clang_format#replace(ranges, ...) abort
     call s:verify_command()
 
     let pos_save = a:0 >= 1 ? a:1 : getpos('.')
-    let formatted = clang_format#format(a:line1, a:line2)
+    let formatted = clang_format#format(a:ranges)
     if !s:success(formatted)
         call s:error_message(formatted)
         return
@@ -256,7 +270,7 @@ function! s:format_inserted_area() abort
     let pos = getpos('.')
     " When in the same buffer
     if &modified && ! empty(s:pos_on_insertenter) && s:pos_on_insertenter[0] == pos[0]
-        call clang_format#replace(s:pos_on_insertenter[1], line('.'))
+        call clang_format#replace([[s:pos_on_insertenter[1], line('.')]])
         let s:pos_on_insertenter = []
     endif
 endfunction
@@ -291,6 +305,65 @@ endfunction
 function! clang_format#disable_auto_format() abort
     let g:clang_format#auto_format = 0
 endfunction
+" s:chdir will change the directory respecting
+" local/tab-local/global directory settings.
+function! s:chdir(dir)
+    " This is a dirty hack to fix tcd breakages on neovim.
+    " Future work should be based on nvim API.
+    if exists(':tcd')
+        let chdir = haslocaldir() ? 'lcd' : haslocaldir(-1, 0) ? 'tcd' : 'cd'
+    else
+        let chdir = exists('*haslocaldir') && haslocaldir() ? 'lcd' : 'cd'
+    endif
+    execute chdir fnameescape(a:dir)
+endfunction
+
+" s:strip: helper function to strip a string
+function! s:strip(string)
+    return substitute(a:string, '^\s*\(.\{-}\)\s*\n\=$', '\1', '')
+endfunction
+
+function! clang_format#do_auto_format_git_diff()
+    let dir = getcwd()
+    let cur_file = expand("%:p")
+    let cur_file_path = isdirectory(cur_file) ? cur_file : fnamemodify(cur_file, ":h")
+    try
+        call s:chdir(cur_file_path)
+        let top_dir=s:strip(system(
+                    \ g:clang_format#git." rev-parse --show-toplevel"))
+        call s:chdir(top_dir)
+        let cur_file = s:system(
+                    \ g:clang_format#git." ls-files --error-unmatch ".cur_file)
+        let source = join(getline(1, '$'), "\n")
+        let ranges = s:system(
+                    \ 'diff <('.g:clang_format#git.' show :'.cur_file.') - '
+                    \ '--old-group-format="" --unchanged-group-format="" '
+                    \ '--new-group-format="%dF-%dL%c''\\012''" '
+                    \ '--changed-group-format="%dF-%dL%c''\\012''"',
+                    \ source)
+        let ranges = split(ranges, '\n')
+        let ranges = map(ranges, "split(v:val, '-')")
+        call clang_format#replace(ranges)
+    catch
+        " not in a git dir, or not a tracked file
+        return 1
+    finally
+        call s:chdir(dir)
+    endtry
+    return 0
+endfunction
+
+function! clang_format#do_auto_format()
+    if g:clang_format#auto_format_git_diff
+        let ret = clang_format#do_auto_format_git_diff()
+        if ret == 0 ||
+           \ g:clang_format#auto_format_git_diff_fallback != 'file'
+            return
+        endif
+    endif
+    call clang_format#replace([[1, line('$')]])
+endfunction
+
 " }}}
 let &cpo = s:save_cpo
 unlet s:save_cpo

doc/clang-format.txt

@@ -127,6 +127,11 @@ g:clang_format#command                                  *g:clang_format#command*
     Name of clang-format command.
     The default value is "clang-format".
 
+g:clang_format#git                                          *g:clang_format#git*
+
+    Name of the git command.
+    The default value is "git".
+
 g:clang_format#code_style                            *g:clang_format#code_style*
 
     Base coding style for formatting.  Available coding styles are "llvm",
@@ -186,6 +191,25 @@ g:clang_format#auto_format                          *g:clang_format#auto_format*
     buffer on saving the buffer.  Formatting is executed at |BufWritePre| event.
     The default value is 0.
 
+g:clang_format#auto_format_git_diff        *g:clang_format#auto_format_git_diff*
+
+    When this value is 1, and when g:clang_format#auto_format is 1, the auto
+    format only formats modified lines is the file is tracked in git.
+    If the file is not tracked, or even not in a git project, fallback
+    behavior depends on |g:clang_format#auto_format_git_diff_fallback|.
+    WARNING: this option should not be used with
+    |g:clang_format#auto_format_on_insert_leave|.
+    The default value is 0.
+
+g:clang_format#auto_format_git_diff_fallback
+                                  *g:clang_format#auto_format_git_diff_fallback*
+
+    Fallback behavior when |g:clang_format#auto_format_git_diff| is 1 and the
+    current file is not tracked. The value can be:
+    - 'file': the whole file is formatted (which is the default
+      |g:clang_format#auto_format| behavior).
+    - 'pass': the file is not formatted.
+
 g:clang_format#auto_format_on_insert_leave
                                     *g:clang_format#auto_format_on_insert_leave*
 

plugin/clang_format.vim

@@ -22,7 +22,7 @@ augroup plugin-clang-format-auto-format
         \ if &ft =~# '^\%(c\|cpp\|objc\|java\|javascript\|typescript\|proto\|arduino\)$' &&
         \     g:clang_format#auto_format &&
         \     !clang_format#is_invalid() |
-        \     call clang_format#replace(1, line('$')) |
+        \     call clang_format#do_auto_format() |
         \ endif
     autocmd FileType c,cpp,objc,java,javascript,typescript,proto,arduino
         \ if g:clang_format#auto_format_on_insert_leave &&