[stdlib] Surface NSKeyedArchiver issues in Xcode.

By calling through to swift_reportToDebugger, Xcode can pick up the
NSKeyedArchiver/Unarchiver issues with Swift classes and display them
in the Issues Navigator. This increases the probability that they'll
be seen and acted upon.

This is not a fully-general interface yet, please do not start hooking
random things up to it. Especially if you're working on something that
doesn't ship with Xcode itself. :-)

rdar://problem/32900735

Author: jrose-apple

stdlib/public/SDK/Foundation/CheckClass.mm

@@ -20,6 +20,9 @@ static bool isASCIIIdentifierChar(char c) {
   return false;
 }
 
+template <typename T, size_t N>
+static constexpr size_t arrayLength(T (&)[N]) { return N; }
+
 static void logIfFirstOccurrence(Class objcClass, void (^log)(void)) {
   static auto queue = dispatch_queue_create(
       "SwiftFoundation._checkClassAndWarnForKeyedArchivingQueue",
@@ -164,26 +167,52 @@ + (int)_swift_checkClassAndWarnForKeyedArchiving:(Class)objcClass
                                                       /*qualified*/true);
       NSString *demangledString = demangledName.newNSStringNoCopy();
       NSString *mangledString = NSStringFromClass(objcClass);
+
+      NSString *primaryMessage;
       switch (operation) {
       case 1:
-        NSLog(@"Attempting to unarchive generic Swift class '%@' with mangled "
-               "runtime name '%@'. Runtime names for generic classes are "
-               "unstable and may change in the future, leading to "
-               "non-decodable data.", demangledString, mangledString);
+        primaryMessage = [[NSString alloc] initWithFormat:
+            @"Attempting to unarchive generic Swift class '%@' with mangled "
+             "runtime name '%@'. Runtime names for generic classes are "
+             "unstable and may change in the future, leading to "
+             "non-decodable data.", demangledString, mangledString];
         break;
       default:
-        NSLog(@"Attempting to archive generic Swift class '%@' with mangled "
-               "runtime name '%@'. Runtime names for generic classes are "
-               "unstable and may change in the future, leading to "
-               "non-decodable data.", demangledString, mangledString);
+        primaryMessage = [[NSString alloc] initWithFormat:
+            @"Attempting to archive generic Swift class '%@' with mangled "
+             "runtime name '%@'. Runtime names for generic classes are "
+             "unstable and may change in the future, leading to "
+             "non-decodable data.", demangledString, mangledString];
         break;
       }
-      NSLog(@"To avoid this failure, create a concrete subclass and register "
-             "it with NSKeyedUnarchiver.setClass(_:forClassName:) instead, "
-             "using the name \"%@\".", mangledString);
-      NSLog(@"If you need to produce archives compatible with older versions "
-             "of your program, use NSKeyedArchiver.setClassName(_:for:) "
-             "as well.");
+      NSString *generatedNote = [[NSString alloc] initWithFormat:
+          @"To avoid this failure, create a concrete subclass and register "
+           "it with NSKeyedUnarchiver.setClass(_:forClassName:) instead, "
+           "using the name \"%@\".", mangledString];
+      const char *staticNote =
+          "If you need to produce archives compatible with older versions "
+          "of your program, use NSKeyedArchiver.setClassName(_:for:) as well.";
+
+      NSLog(@"%@", primaryMessage);
+      NSLog(@"%@", generatedNote);
+      NSLog(@"%s", staticNote);
+
+      RuntimeErrorDetails::Note notes[] = {
+        { [generatedNote UTF8String], /*numFixIts*/0, /*fixIts*/nullptr },
+        { staticNote, /*numFixIts*/0, /*fixIts*/nullptr },
+      };
+
+      RuntimeErrorDetails errorInfo = {};
+      errorInfo.version = RuntimeErrorDetails::currentVersion;
+      errorInfo.errorType = "nskeyedarchiver-incompatible-class";
+      errorInfo.notes = notes;
+      errorInfo.numNotes = arrayLength(notes);
+
+      _swift_reportToDebugger(RuntimeErrorFlagNone, [primaryMessage UTF8String],
+                              &errorInfo);
+
+      [primaryMessage release];
+      [generatedNote release];
       [demangledString release];
     });
     return 1;
@@ -196,23 +225,28 @@ + (int)_swift_checkClassAndWarnForKeyedArchiving:(Class)objcClass
     StringRefLite demangledName = swift_getTypeName(theClass,/*qualified*/true);
     NSString *demangledString = demangledName.newNSStringNoCopy();
     NSString *mangledString = NSStringFromClass(objcClass);
+
+    NSString *primaryMessage;
     switch (operation) {
     case 1:
-      NSLog(@"Attempting to unarchive Swift class '%@' with mangled runtime "
-             "name '%@'. The runtime name for this class is unstable and may "
-             "change in the future, leading to non-decodable data.",
-             demangledString, mangledString);
+      primaryMessage = [[NSString alloc] initWithFormat:
+          @"Attempting to unarchive Swift class '%@' with mangled runtime "
+           "name '%@'. The runtime name for this class is unstable and may "
+           "change in the future, leading to non-decodable data.",
+          demangledString, mangledString];
       break;
     default:
-      NSLog(@"Attempting to archive Swift class '%@' with mangled runtime "
-             "name '%@'. The runtime name for this class is unstable and may "
-             "change in the future, leading to non-decodable data.",
-             demangledString, mangledString);
+      primaryMessage = [[NSString alloc] initWithFormat:
+          @"Attempting to archive Swift class '%@' with mangled runtime "
+           "name '%@'. The runtime name for this class is unstable and may "
+           "change in the future, leading to non-decodable data.",
+          demangledString, mangledString];
       break;
     }
-    [demangledString release];
-    NSLog(@"You can use the 'objc' attribute to ensure that the name will not "
-           "change: \"@objc(%@)\"", mangledString);
+
+    NSString *firstNote = [[NSString alloc] initWithFormat:
+        @"You can use the 'objc' attribute to ensure that the name will not "
+         "change: \"@objc(%@)\"", mangledString];
 
     StringRefLite baseName = findBaseName(demangledName);
     // Offer a more generic message if the base name we found doesn't look like
@@ -222,9 +256,35 @@ + (int)_swift_checkClassAndWarnForKeyedArchiving:(Class)objcClass
       baseName = "MyModel";
     }
 
-    NSLog(@"If there are no existing archives containing this class, you "
-           "should choose a unique, prefixed name instead: "
-           "\"@objc(ABC%1$.*2$s)\"", baseName.data, (int)baseName.length);
+    NSString *secondNote = [[NSString alloc] initWithFormat:
+        @"If there are no existing archives containing this class, you should "
+         "choose a unique, prefixed name instead: \"@objc(ABC%1$.*2$s)\"",
+        baseName.data, (int)baseName.length];
+
+    NSLog(@"%@", primaryMessage);
+    NSLog(@"%@", firstNote);
+    NSLog(@"%@", secondNote);
+
+    // FIXME: We could suggest these as fix-its if we had source locations for
+    // the class.
+    RuntimeErrorDetails::Note notes[] = {
+      { [firstNote UTF8String], /*numFixIts*/0, /*fixIts*/nullptr },
+      { [secondNote UTF8String], /*numFixIts*/0, /*fixIts*/nullptr },
+    };
+
+    RuntimeErrorDetails errorInfo = {};
+    errorInfo.version = RuntimeErrorDetails::currentVersion;
+    errorInfo.errorType = "nskeyedarchiver-incompatible-class";
+    errorInfo.notes = notes;
+    errorInfo.numNotes = arrayLength(notes);
+
+    _swift_reportToDebugger(RuntimeErrorFlagNone, [primaryMessage UTF8String],
+                            &errorInfo);
+
+    [primaryMessage release];
+    [firstNote release];
+    [secondNote release];
+    [demangledString release];
   });
   return 2;
 }