fix: this commit addresses issue #2

- mark code blocks as `rust` before sending content to popup window;
- in neovim, set the local `conceallevel` to `2` in the popup window,
  did not find the equivalent in vim (please help pointing out if there
  is any);
- mark the content title as level one header
- remove the trailing white spaces if in neovim, those spaces were
  meant to be used as padding as popup window lacks padding option in
  neovim, remove them for now;
- add tests for the function that mark code blocks as `rust`

Ref: [issue 2](#2)

Author: yining

autoload/rustcexplain/popup.vim

@@ -3,8 +3,11 @@ set cpoptions&vim
 
 
 function! rustcexplain#popup#OpenPopupWindow(rustc_cmd, err_code) abort
+  let l:message = systemlist(a:rustc_cmd)
+  let l:message = s:mark_code_blocks_as_rust(l:message)
+
   let l:winid = popup_create(
-        \ systemlist(a:rustc_cmd),
+        \ l:message,
         \ { 'title': '  Explain [' . a:err_code . ']  ',
         \  'close': 'button',
         \  'pos': 'center',
@@ -26,8 +29,8 @@ endfunction
 
 function! rustcexplain#popup#OpenNeovimFloatWindow(rustc_cmd, err_code) abort
   let l:message = systemlist(a:rustc_cmd)
-  let l:message = ['Explain [' . a:err_code .']', ''] + l:message
-  let l:message = map(l:message, {k, v -> ' ' . v . ' '})
+  let l:message = ['# Explain [' . a:err_code .']', ''] + l:message
+  let l:message = s:mark_code_blocks_as_rust(l:message)
 
   let l:uis = nvim_list_uis()
   if len(l:uis) > 0
@@ -57,6 +60,7 @@ function! rustcexplain#popup#OpenNeovimFloatWindow(rustc_cmd, err_code) abort
         \ }
   let l:winid = nvim_open_win(l:buf, 1, l:opts)
   call nvim_win_set_option(l:winid, 'winhl', 'Normal:Cursorline')
+  call nvim_set_option_value('conceallevel', 2, {'win': l:winid, 'scope': 'local'})
   call nvim_buf_set_var(l:buf, 'ale_enabled', 0)
 
   call setbufvar(winbufnr(l:winid),  '&filetype',  'markdown')
@@ -69,6 +73,21 @@ function! rustcexplain#popup#OpenNeovimFloatWindow(rustc_cmd, err_code) abort
   endfor
 endfunction
 
+" to mark code blocks in `rustc --explain` as `rust` as requested in
+" https://github.com/yining/vim-rustcexplain/issues/2
+function! s:mark_code_blocks_as_rust(lines) abort
+  let l:lines = []
+  " only change the opening '```' to '```rust'
+  let l:opening_flag = v:true
+  for l:line in a:lines
+    if match(l:line, '^\s*```\s*$') >= 0
+      let l:line = l:opening_flag ? '```rust' : l:line
+      let l:opening_flag = !l:opening_flag
+    endif
+    let l:lines = l:lines + [l:line]
+  endfor
+  return l:lines
+endfunction
 
 " ref: https://github.com/prabirshrestha/vim-lsp/issues/975#issuecomment-751658462
 function! s:popup_filter(winid, key) abort

test/mark_code_block_rust_tests.vim

@@ -0,0 +1,74 @@
+scriptencoding utf8
+
+let s:suite = themis#suite('tests code blocks are properly marked as rust')
+let s:assert = themis#helper('assert')
+let s:scope = themis#helper('scope')
+
+function! s:suite.before_each()
+  let s:funcs = s:scope.funcs('autoload/rustcexplain/popup.vim')
+endfunction
+
+function! s:suite.after_each()
+endfunction
+
+function! s:suite.test_empty()
+  let l:input = []
+  let l:expected = []
+  let l:result = s:funcs.mark_code_blocks_as_rust(l:input)
+  call s:assert.equals(l:expected, l:result)
+endfunction
+
+function! s:suite.test_one_block()
+  let l:input = [
+        \ '```',
+        \ 'code',
+        \ '```',
+        \]
+  let l:expected = [
+        \ '```rust',
+        \ 'code',
+        \ '```',
+        \]
+  let l:result = s:funcs.mark_code_blocks_as_rust(l:input)
+  call s:assert.equals(l:expected, l:result)
+endfunction
+
+function! s:suite.test_one_and_half_block()
+  let l:input = [
+        \ '```',
+        \ 'code',
+        \ '```',
+        \ '```',
+        \ 'code',
+        \]
+  let l:expected = [
+        \ '```rust',
+        \ 'code',
+        \ '```',
+        \ '```rust',
+        \ 'code',
+        \]
+  let l:result = s:funcs.mark_code_blocks_as_rust(l:input)
+  call s:assert.equals(l:expected, l:result)
+endfunction
+
+function! s:suite.test_simple()
+  let l:input = [
+        \ '```',
+        \ '```',
+        \ '```',
+        \ '```',
+        \ '```',
+        \ '```',
+        \]
+  let l:expected = [
+        \ '```rust',
+        \ '```',
+        \ '```rust',
+        \ '```',
+        \ '```rust',
+        \ '```',
+        \]
+  let l:result = s:funcs.mark_code_blocks_as_rust(l:input)
+  call s:assert.equals(l:expected, l:result)
+endfunction