cmake: Delay computation of crtbegin/crtend paths until needed

With inclusion of the optimization flag into the multilib selection
process, we cannot compute the compiler library path when the compiler's
target.cmake is processed as OPTIMIZATION_FLAG is not computed until much
later.

Instead, have that file expose a function (library_file_path) which can be
used to locate the appropriate crtbegin.o and crtend.o files.

Stop adding the (possibly incorrect) libgcc directory to LIB_INCLUDE_DIR as
the compiler will include the correct directory at link time anyways.

For icx, leave code in which discovers whether libgcc.a is available with
the assumption that if a libgcc.a is available with one set of compiler
options the correct libgcc.a will be available with the final set of
compiler options.

Signed-off-by: Keith Packard <[email protected]>

Author: keith-packard

cmake/compiler/gcc/target.cmake

@@ -96,20 +96,19 @@ if(SYSROOT_DIR)
   set(LIBC_LIBRARY_DIR "\"${SYSROOT_DIR}\"/lib/${NEWLIB_DIR}")
 endif()
 
-# This libgcc code is partially duplicated in compiler/*/target.cmake
-execute_process(
-  COMMAND ${CMAKE_C_COMPILER} ${TOOLCHAIN_C_FLAGS} --print-libgcc-file-name
-  OUTPUT_VARIABLE LIBGCC_FILE_NAME
-  OUTPUT_STRIP_TRAILING_WHITESPACE
-  )
-
-assert_exists(LIBGCC_FILE_NAME)
-
-get_filename_component(LIBGCC_DIR ${LIBGCC_FILE_NAME} DIRECTORY)
-
-assert_exists(LIBGCC_DIR)
+# Search for filename in default compiler library path
 
-set_linker_property(PROPERTY lib_include_dir "-L\"${LIBGCC_DIR}\"")
+function(library_file_path filename i)
+  execute_process(
+    COMMAND ${CMAKE_C_COMPILER} ${TOOLCHAIN_C_FLAGS} ${OPTIMIZATION_FLAG} --print-file-name ${filename}
+    OUTPUT_VARIABLE filepath
+    OUTPUT_STRIP_TRAILING_WHITESPACE
+    )
+  if(${filepath} STREQUAL ${filename})
+    set(filepath "")
+  endif()
+  set(${i} "${filepath}" PARENT_SCOPE)
+endfunction()
 
 # For CMake to be able to test if a compiler flag is supported by the
 # toolchain we need to give CMake the necessary flags to compile and

cmake/compiler/icx/target.cmake

@@ -45,18 +45,29 @@ else()
   list(APPEND TOOLCHAIN_C_FLAGS "-m32")
 endif()
 
+# Search for filename in default compiler library path
+
+function(library_file_path filename i)
+  execute_process(
+    COMMAND ${CMAKE_C_COMPILER} ${TOOLCHAIN_C_FLAGS} ${OPTIMIZATION_FLAG} --print-file-name ${filename}
+    OUTPUT_VARIABLE filepath
+    OUTPUT_STRIP_TRAILING_WHITESPACE
+    )
+  set(${i} ${filepath} PARENT_SCOPE)
+endfunction()
+
+# Add -lgcc if available
 
 # This libgcc code is partially duplicated in compiler/*/target.cmake
 execute_process(
   COMMAND ${CMAKE_C_COMPILER} ${TOOLCHAIN_C_FLAGS} --print-libgcc-file-name
-  OUTPUT_VARIABLE LIBGCC_FILE_NAME
+  OUTPUT_VARIABLE libgcc_file_name
   OUTPUT_STRIP_TRAILING_WHITESPACE
   )
 
-get_filename_component(LIBGCC_DIR ${LIBGCC_FILE_NAME} DIRECTORY)
+get_filename_component(libgcc_dir ${libgcc_file_name} DIRECTORY)
 
-list(APPEND LIB_INCLUDE_DIR "-L\"${LIBGCC_DIR}\"")
-if(LIBGCC_DIR)
+if(libgcc_dir)
   list(APPEND TOOLCHAIN_LIBS gcc)
 endif()
 

cmake/compiler/xcc/target.cmake

@@ -40,16 +40,16 @@ foreach(file_name include/stddef.h include-fixed/limits.h)
   list(APPEND NOSTDINC ${_OUTPUT})
 endforeach()
 
-# This libgcc code is partially duplicated in compiler/*/target.cmake
-execute_process(
-  COMMAND ${CMAKE_C_COMPILER} ${TOOLCHAIN_C_FLAGS} --print-libgcc-file-name
-  OUTPUT_VARIABLE LIBGCC_FILE_NAME
-  OUTPUT_STRIP_TRAILING_WHITESPACE
-  )
+# Search for filename in default compiler library path
 
-get_filename_component(LIBGCC_DIR ${LIBGCC_FILE_NAME} DIRECTORY)
-
-list(APPEND LIB_INCLUDE_DIR "-L\"${LIBGCC_DIR}\"")
+function(library_file_path filename i)
+  execute_process(
+    COMMAND ${CMAKE_C_COMPILER} ${TOOLCHAIN_C_FLAGS} ${OPTIMIZATION_FLAG} --print-file-name ${filename}
+    OUTPUT_VARIABLE filepath
+    OUTPUT_STRIP_TRAILING_WHITESPACE
+    )
+  set(${i} ${filepath} PARENT_SCOPE)
+endfunction()
 
 # For CMake to be able to test if a compiler flag is supported by the
 # toolchain we need to give CMake the necessary flags to compile and

cmake/linker/ld/target.cmake

@@ -164,10 +164,12 @@ macro(toolchain_linker_finalize)
 
   set(cpp_link "${common_link}")
   if(NOT "${ZEPHYR_TOOLCHAIN_VARIANT}" STREQUAL "host")
-    if(CONFIG_CPP_EXCEPTIONS AND LIBGCC_DIR)
+    library_file_path(crtbegin.o CRTBEGIN_PATH)
+    library_file_path(crtend.o CRTEND_PATH)
+    if(CONFIG_CPP_EXCEPTIONS AND CRTBEGIN_PATH AND CRTEND_PATH)
       # When building with C++ Exceptions, it is important that crtbegin and crtend
       # are linked at specific locations.
-      set(cpp_link "<LINK_FLAGS> ${LIBGCC_DIR}/crtbegin.o ${link_libraries} ${LIBGCC_DIR}/crtend.o")
+      set(cpp_link "<LINK_FLAGS> ${CRTBEGIN_PATH} ${link_libraries} ${CRTEND_PATH}")
     endif()
   endif()
   set(CMAKE_CXX_LINK_EXECUTABLE "<CMAKE_CXX_COMPILER> <FLAGS> <CMAKE_CXX_LINK_FLAGS> ${cpp_link}")

cmake/linker/xt-ld/target.cmake

@@ -11,14 +11,16 @@ find_program(CMAKE_LINKER xt-ld ${LD_SEARCH_PATH})
 
 set_ifndef(LINKERFLAGPREFIX -Wl)
 
-if(CONFIG_CPP_EXCEPTIONS)
+library_file_path(crtbegin.o CRTBEGIN_PATH)
+library_file_path(crtend.o CRTEND_PATH)
+if(CONFIG_CPP_EXCEPTIONS AND CRTBEGIN_PATH AND CRTEND_PATH)
   # When building with C++ Exceptions, it is important that crtbegin and crtend
   # are linked at specific locations.
   # The location is so important that we cannot let this be controlled by normal
   # link libraries, instead we must control the link command specifically as
   # part of toolchain.
   set(CMAKE_CXX_LINK_EXECUTABLE
-      "<CMAKE_CXX_COMPILER> <FLAGS> <CMAKE_CXX_LINK_FLAGS> <LINK_FLAGS> ${LIBGCC_DIR}/crtbegin.o <OBJECTS> -o <TARGET> <LINK_LIBRARIES> ${LIBGCC_DIR}/crtend.o")
+      "<CMAKE_CXX_COMPILER> <FLAGS> <CMAKE_CXX_LINK_FLAGS> <LINK_FLAGS> ${CRTBEGIN_PATH} <OBJECTS> -o <TARGET> <LINK_LIBRARIES> ${CRTEND_PATH}")
 endif()
 
 # Run $LINKER_SCRIPT file through the C preprocessor, producing ${linker_script_gen}