main: Add ' helper function

Author: phy1729

highlighters/main/main-highlighter.zsh

@@ -49,6 +49,7 @@
 : ${ZSH_HIGHLIGHT_STYLES[dollar-double-quoted-argument]:=fg=cyan}
 : ${ZSH_HIGHLIGHT_STYLES[back-double-quoted-argument]:=fg=cyan}
 : ${ZSH_HIGHLIGHT_STYLES[back-dollar-quoted-argument]:=fg=cyan}
+: ${ZSH_HIGHLIGHT_STYLES[rc-quote]:=fg=cyan}
 : ${ZSH_HIGHLIGHT_STYLES[assign]:=none}
 : ${ZSH_HIGHLIGHT_STYLES[redirection]:=none}
 : ${ZSH_HIGHLIGHT_STYLES[comment]:=fg=black,bold}
@@ -214,6 +215,11 @@ _zsh_highlight_highlighter_main_paint()
   else
     integer path_dirs_was_set=0
   fi
+  if [[ -o rc_quotes ]]; then
+    integer rc_quotes=1
+  else
+    integer rc_quotes=0
+  fi
   if [[ -o multi_func_def ]]; then
     integer multi_func_def=1
   else
@@ -677,7 +683,9 @@ _zsh_highlight_highlighter_main_paint()
                  ;|
         '--'*)   style=double-hyphen-option;;
         '-'*)    style=single-hyphen-option;;
-        "'"*)    style=single-quoted-argument;;
+        "'"*)    _zsh_highlight_main_highlighter_highlight_single_quote 1
+                 already_added=1
+                 ;;
         '"'*)    _zsh_highlight_main_highlighter_highlight_double_quote
                  already_added=1
                  ;;
@@ -804,6 +812,28 @@ _zsh_highlight_main_highlighter_check_path()
   return 1
 }
 
+# Highlight single-quoted strings
+_zsh_highlight_main_highlighter_highlight_single_quote()
+{
+  local arg1=$1 i q=\'
+  i=$arg[(ib:arg1+1:)$q]
+
+  if (( rc_quotes )); then
+    local -a highlights
+    while [[ $arg[i+1] == "'" ]]; do
+      highlights+=($(( start_pos + i - 1 )) $(( start_pos + ++i )) rc-quote)
+      i=$arg[(ib:i+1:)$q]
+    done
+
+    highlights+=($(( start_pos + $1 - 1 )) $(( start_pos + i )) single-quoted-argument $highlights)
+    _zsh_highlight_main_add_region_highlights $highlights
+  else
+    _zsh_highlight_main_add_region_highlight $(( start_pos + $1 - 1)) $(( start_pos + i )) single-quoted-argument
+  fi
+
+  REPLY=$i
+}
+
 # Highlight special chars inside double-quoted strings
 _zsh_highlight_main_highlighter_highlight_double_quote()
 {