Fix #3441: parentheses wrapping expression throw invalid error

src/grammar.coffee

@@ -333,7 +333,11 @@ grammar =
   Value: [
     o 'Assignable'
     o 'Literal',                                -> new Value $1
-    o 'Parenthetical',                          -> new Value $1
+    o 'Parenthetical',                          ->
+        if $1.hasParentheses()
+          new Value $1
+        else
+          $1
     o 'Range',                                  -> new Value $1
     o 'Invocation',                             -> new Value $1
     o 'This'
@@ -597,8 +601,20 @@ grammar =
   # where only values are accepted, wrapping it in parentheses will always do
   # the trick.
   Parenthetical: [
-    o '( Body )',                               -> new Parens $2
-    o '( INDENT Body OUTDENT )',                -> new Parens $3
+    o '( Body )',                               ->
+        # When `Parens` block includes a `StatementLiteral` (e.g. `(b; break) for a in arr`),
+        # it won't compile since `Parens` (`(b; break)`) is compiled as `Value` and
+        # pure statement (`break`) can't be used in an expression.
+        # For this reasons, we return `Block`, which is passed further to `Value` and `Expression`.
+        if $2.hasStatementLiteral()
+          LOC(2)(Block.wrap [$2])
+        else
+          new Parens $2
+    o '( INDENT Body OUTDENT )',                ->
+        if $3.hasStatementLiteral()
+          LOC(3)(Block.wrap [$3])
+        else
+          new Parens $3
   ]
 
   # The condition portion of a while loop.

src/nodes.coffee

@@ -388,6 +388,12 @@ exports.Base = class Base
       answer = answer.concat fragments
     answer
 
+  hasStatementLiteral: ->
+    @contains (n) -> n instanceof StatementLiteral
+
+  hasParentheses: ->
+    @ instanceof Parens
+
 #### HoistTarget
 
 # A **HoistTargetNode** represents the output location in the node tree for a hoisted node.

test/control_flow.coffee

@@ -484,3 +484,34 @@ test "#4267: lots of for-loops in the same scope", ->
       true
   """
   ok CoffeeScript.eval(code)
+
+# Issue #3441: Parentheses wrapping expression throw invalid error in `then` clause
+test "#3441: `StatementLiteral` in parentheses", ->
+  i = 0
+  r1 = ((i++; break) while i < 10)
+  arrayEq r1, []
+
+  i = 0
+  r2 = ((i++; continue) while i < 10)
+  arrayEq r2, []
+
+  i = 0
+  r4 = while i < 10 then (i++; break)
+  arrayEq r4, []
+
+  i = 0
+  r5 = while i < 10 then (i++; continue)
+  arrayEq r5, []
+
+  arr = [0..9]
+  r6 = ((a; break) for a in arr)
+  arrayEq r6, []
+
+  r7 = ((a; continue) for a in arr)
+  arrayEq r7, []
+
+  r8 = for a in arr then (a; break)
+  arrayEq r8, []
+
+  r9 = for a in arr then (a; continue)
+  arrayEq r9, []